Jak powiązać RadioGroup z Memo

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Witam wszystkich bardzo serdecznie. Mam duży problem z konwersją kodu z C++ do Delphi. Delphi uczę się od podstaw. Mam dokładnie taką samą swoją sytuację z jak z wątku: https://4programmers.net/Forum/C_i_C++/234123-jak_powiazac_radiogroup_z_memo?p=1036179#id1036179.

W C++ mam:

Kopiuj

void __fastcall TForm1::ComboBox1Select(TObject *Sender)
{
        if (ComboBox1->Text == "A1")
        {
                String sFileName1 = ExtractFilePath(ParamStr(0)) + "dat\\a1pik.dat";
                String sFileName2 = ExtractFilePath(ParamStr(0)) + "dat\\uwagia1.dat";

                if(!FileExists)
                {
                        Application->MessageBox(("Nie odnaleziono pliku '" + ExtractFilePath(ParamStr(0)) + "dat\\a1pik.dat'!").c_str(), "Uwaga! Brak pliku", MB_OK | MB_ICONSTOP);
                        RadioGroup1->Items->Clear();
                        powiat->Caption = "Nie wybrano żadnej opcji...";
                        Memo1->Clear();
                        return;
                }

                Lista->Clear();
                Lista->LoadFromFile(sFileName1);

                RadioGroup1->Visible = true;
                RadioGroup1->Items->Clear();
                powiat->Caption = "Nie wybrano żadnej opcji...";
                Memo1->Clear();

                for(int i = 0; i < Lista->Count; i++)
                {
                        RadioGroup1->Items->Add(Lista->Names[i]);
                }

Dalej dla RadioGroup1Click():

Kopiuj

Memo1->Clear();
Memo1->Lines->Append(Lista->Values[Lista->Names[RadioGroup1->ItemIndex]]);

I w pliku .h deklarację:

Kopiuj

private:    // User declarations
        THashedStringList *Lista;

W Delphi dodałem zmienne:

Kopiuj

var
  Form1: TForm1;
  lista_drog: TStringList;
  liczba_drog: Integer;

Kopiuj

procedure TForm1.ComboBox1Select(Sender: TObject);
begin

     if (ComboBox1.Text = 'A1') then
     begin
          lista_drog := TStringList.Create;
          if FileExists('dat\a1pik.dat') then
          begin
               lista_drog.LoadFromFile('dat\a1pik.dat');
               RadioGroup1.Visible := true;
               RadioGroup1.Items.Clear;

               for liczba_drog := 0 to lista_drog.Count-1 do
               begin
                    RadioGroup1.Items.Add(lista_drog.Names[liczba_drog]);
               end
          end
          else
              begin
                   MessageDlg('Nie odnaleziono pliku: ' + ExtractFilePath(Application.ExeName) + 'dat\a1pik.dat' + '.' , mtError, [mbOk], 0 );
                   RadioGroup1.Items.Clear;
                   powiat.Caption := 'Nie wybrano żadnej opcji...';
                   Memo1.Clear;
              end
          end;
     lista_drog.Free;
     end;

Do RadioClicka nawet nie doszedłem.

Jednak nie otrzymuję takie samego efektu jak w C++. Czy możecie mi jakoś pomóc. Chodzi o wczytanie pliku do zmiennej StringList i później pobranie wartości Names do RadioBox przy sprawdzeniu warunków istnieja pliku.

flowCRANE

2017-03-06 21:08

flowCRANE2017-03-06 21:08

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

0

Kopiuj

for liczba_drog := 0 to lista_drog.Count-1 do
begin
  RadioGroup1.Items.Add(lista_drog.Names[liczba_drog]);
end;

Szybciej jest zrobić tak:

Kopiuj

RadioGroup1.Items.Assign(lista_drog);

A tak w ogóle to nie rozumiem czego nie rozumiesz - zadaj jakieś konkretne pytanie. I wywal te zmienne globalne, bo nie muszą być globalne. Nazwij je sensownie i zrób z nich prywatne pola klasy formularza - będzie nieco lepiej.

edytowany 2x, ostatnio: flowCRANE 2017-03-06 21:10

Slowik86

2017-03-06 21:33

Slowik862017-03-06 21:33

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Mam plik z danymi typu:

Kopiuj

264,801 - 270,529 km=Powiat Łęczycki
270,529 - 271,476 km=Powiat Łowicki
271,476 - 273,697 km=Powiat Łęczycki

I chciałbym pierwsze wartości umieścić w RadioGroup, następnie po kliknięciu danej wartości w RadioGroup miałaby się wyświetlić drug wartość w Memo. To po pierwsze ;)

A po drugie: tak jak wspomniałem uczę się Delphi i się zakręciłem z tyloma end'ami ;)

Kopiuj

     if (ComboBox1.Text = 'A1') then
     begin
          lista_drog := TStringList.Create;
          if FileExists('dat\a1pik.dat') then
          begin
               lista_drog.LoadFromFile('dat\a1pik.dat');
               RadioGroup1.Visible := true;
               RadioGroup1.Items.Clear;

               for liczba_drog := 0 to lista_drog.Count-1 do
               begin
                    RadioGroup1.Items.Add(lista_drog.Names[liczba_drog]);
               end
          end
          else
              begin
                   MessageDlg('Nie odnaleziono pliku: ' + ExtractFilePath(Application.ExeName) + 'dat\a1pik.dat' + '.' , mtError, [mbOk], 0 );
                   RadioGroup1.Items.Clear;
                   powiat.Caption := 'Nie wybrano żadnej opcji...';
                   Memo1.Clear;
              end;

     lista_drog.Free;
     end;

end;

Czy możecie zerknąć czy składnia jest dobra? :) Działać działa, ale chciałbym pisać dobrze.

edytowany 3x, ostatnio: flowCRANE 2017-03-06 21:44

flowCRANE

2017-03-06 21:47

flowCRANE2017-03-06 21:47

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

1

I chciałbym pierwsze wartości umieścić w RadioGroup, następnie po kliknięciu danej wartości w RadioGroup miałaby się wyświetlić drug wartość w Memo.

A które to są pierwsze wartości, a które te drugie? Opisz problem szczegółowo, tak aby nie tracić czasu na domyślanie się.

A po drugie: tak jak wspomniałem uczę się Delphi i się zakręciłem z tyloma end'ami ;)

Bloki begin end masz akurat dobrze, choć ten end zamykający ciało pętli powinien być zakończony średnikiem.

edytowany 1x, ostatnio: flowCRANE 2017-03-06 21:47

Slowik86

2017-03-06 22:02

Slowik862017-03-06 22:02

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Dziękuję za pomoc z drugim :) Już poprawiam.

W pliku mam taką linijkę: "264,801 - 270,529 km=Powiat Łęczycki"

I teraz chciałbym zgodnie (Przykłąd: http://www.delphibasics.co.uk/RTL.asp?Name=tstringlist) wykorzystać cechy StringList i jego Names w moim przypadku "264,801 - 270,529 km" dać do RadioGroup a dalszą część czyli Values wrzucić do Memo, przy założeniu, że Values w Memo wyświetli się dopiero po kliknięciu odpowiedniego Names w RadioGroup.

Przepraszam jeśli namotałem w opisie :)

P.s. Jest jeszcze DelimitedText, Delimiter and QuoteChar przy StringList.

edytowany 2x, ostatnio: Slowik86 2017-03-06 22:03

flowCRANE

2017-03-07 05:52

flowCRANE2017-03-07 05:52

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

1

Jeśli chcesz korzystać z par name/value to do określenia znaku separatora służy właściwość NameValueSeparator. Przykład użycia niżej:

Kopiuj

uses
  Classes;
var
  List: TStringList;
  ItemIdx: Integer;
  Name, Value: String;
begin
  List := TStringList.Create();
  try
    List.Add('264,801 - 270,529 km=Powiat Łęczycki');
    List.Add('270,529 - 271,476 km=Powiat Łowicki');
    List.Add('271,476 - 273,697 km=Powiat Łęczycki');

    List.NameValueSeparator := '=';

    for ItemIdx := 0 to List.Count - 1 do
    begin
      Name := List.Names[ItemIdx];
      Value := List.Values[Name];

      WriteLn('Name: "', Name, '" | Value: "', Value, '"');
    end;
  finally
    List.Free();
  end;
end.

Zawartość konsoli po wykonaniu:

Kopiuj

Name: "264,801 - 270,529 km" | Value: "Powiat Łęczycki"
Name: "270,529 - 271,476 km" | Value: "Powiat Łowicki"
Name: "271,476 - 273,697 km" | Value: "Powiat Łęczycki"

Czyli działa prawidłowo - możesz to sprawdzić tutaj.

edytowany 3x, ostatnio: flowCRANE 2017-03-07 07:00

Slowik86

2017-03-07 16:07

Slowik862017-03-07 16:07

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Próbuję zrobić jak Ty mówisz mając tylko RadioGroup i Label na formie:

Kopiuj

var
  Form1: TForm1;
  List: TStringList;
  ItemIdx: Integer;
  Name, Value: String;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  List := TStringList.Create();
  List.LoadFromFile('a1pik.dat');
  List.NameValueSeparator := '=';

  for ItemIdx := 0 to List.Count - 1 do
    begin
      Name := List.Names[ItemIdx];
      Value := List.Values[Name];


      end;
  RadioGroup1.Items.Add(Name);
    end;

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
  Label1.Caption := Value;
end;


end.

Jednak wyskakuje błąd w Lazarusie typu: "230,418 km" is not a valid component name :(

flowCRANE

2017-03-07 16:20

flowCRANE2017-03-07 16:20

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

1

Sformatuj ten kod porządnie, bo wcięcia są rozjechane. Ten kod nie jest prawidłowy, dlatego że dodawanie pozycji do grupy masz poza pętlą. Poza tym, Ty nie wiesz czym są zmienne lokalne, że wszystko wszucasz do globali?

Błąd natomiast istnieje w tej linijce:

Kopiuj

Name := List.Names[ItemIdx];

W tym kontekście Name to właściwość formularza, a nie zmienna lokalna, więc zmień nazwę swojej zmiennej, tak aby nie występowała kolizja. Aby sobie ułatwić pisanie, zmienne lokalne możesz poprzedzać prefiksem L.

Kopiuj

type
  TMainForm = class(TForm)
  {..}
  private
    FList: TStringList;
  end;

procedure TForm1.FormCreate(Sender: TObject);
var
  LName, LValue: String;
  LIndex: Integer;
begin
  FList := TStringList.Create();
  FList.LoadFromFile('a1pik.dat');
  FList.NameValueSeparator := '=';

  for LIndex := 0 to FList.Count - 1 do
  begin
    LName := List.Names[LIndex];
    LValue := List.Values[LName];

    RadioGroup1.Items.Add(LName);
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FList.Free();
end;

Slowik86

2017-03-07 16:44

Slowik862017-03-07 16:44

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Poprawiłem w tym miejscu:

Kopiuj

LName := FList.Names[LIndex];
LValue := FList.Values[LName];

Dalej jednak męcze się z błędem w RadioGroup1Click:

Kopiuj

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
  //Label1.Caption := LValue;
  //Label1.Caption := FList.Values[RadioGroup1.ItemIndex];
end;

Próbuję dalej z tym Labelem, ale błędy są typu:

Kopiuj

unit1.pas(55,21) Error: Identifier not found "LValue"
unit1.pas(56,55) Error: Incompatible type for arg no. 1: Got "LongInt", expected "AnsiString"

edytowany 2x, ostatnio: flowCRANE 2017-03-07 16:49

flowCRANE

2017-03-07 16:48

flowCRANE2017-03-07 16:48

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

1

Zmienna LValue - jak prefiks wskazuje - jest zmienną lokalną, więc nie masz do niej dostępu spoza zdarzenia OnCreate... A nawet gdybyś miał to ta zmienna zawierałaby nie wiadomo co (i dlatego właśnie jest lokalną), więc zapomnij o niej.

Kopiuj

Label1.Caption := FList.Values[RadioGroup1.Items[RadioGroup1.ItemIndex]];

edytowany 1x, ostatnio: flowCRANE 2017-03-07 16:50

Slowik86

2017-03-07 16:51

Slowik862017-03-07 16:51

Rejestracja:około 8 lat
Ostatnio:prawie 8 lat
Postów:17

0

Działa :)

Kopiuj

Label1.Caption := FList.Values[FList.Names[RadioGroup1.ItemIndex]];

Dzięki twojej pomocy o poradzie o oznaczaniu zrobiłem tak:

Kopiuj

type

  { TForm1 }

  TForm1 = class(TForm)
    Label1: TLabel;
    RadioGroup1: TRadioGroup;
    procedure FormCreate(Sender: TObject);
    procedure RadioGroup1Click(Sender: TObject);
  private
    { private declarations }
    FList: TStringList;
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
var
  LIndex: Integer;
begin
  FList := TStringList.Create();
  FList.LoadFromFile('a1pik.dat');
  FList.NameValueSeparator := '=';

  for LIndex := 0 to FList.Count - 1 do
  begin
    RadioGroup1.Items.Add(FList.Names[LIndex]);
  end;
end;

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
  Label1.Caption := FList.Values[FList.Names[RadioGroup1.ItemIndex]];
end;

end.

Skorzystałem z globalnej, gdyż jeszcze dalej będę ją używał :) Ale dziękuję serdecznie za naprowadzenie i wszelką pomoc dla tumana - mnie :)

edytowany 3x, ostatnio: Slowik86 2017-03-07 16:55

kAzek 2017-03-07 18:08

Z niczego globalnego nie skorzystałeś w klasach nie ma zmiennych globalnych a tak zadeklarowana zmienna FList jest zmienna prywatną (czyli widoczną przy odwołaniach do klasy i to tylko w module w którym klasa jest zadeklarowana).

flowCRANE

2017-03-07 20:05

flowCRANE2017-03-07 20:05

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12171

0

Mała podpowiedź - zamiast korzystać z właściwości Values, lepiej będzie użyć ValueFromIndex. Poprzednio podałem przykładowy kod używający tych par, gdzie w pętli znajduje się przepisanie nazwy i wartości do zmiennych:

Kopiuj

LName := List.Names[LIndex];
LValue := List.Values[LName];

Ten kod można zapisać też tak (szybsze rozwiązanie):

Kopiuj

LName := List.Names[LIndex];
LValue := List.ValueFromIndex[LIndex];

A jeśli chodzi konkretnie o Twój kod to dzięki temu zawartość handlera RadioGroup1Click uprości się:

Kopiuj

procedure TForm1.RadioGroup1Click(Sender: TObject);
begin
  Label1.Caption := FList.ValueFromIndex[RadioGroup1.ItemIndex];
end;

edytowany 6x, ostatnio: flowCRANE 2017-03-07 20:10

prokopnik

2017-03-08 06:53

prokopnik2017-03-08 06:53

Rejestracja:około 8 lat
Ostatnio:około 8 lat
Postów:1

0

Bardzo mi się to przydało, dzięki !

flowCRANE 2017-03-08 15:15

Proszę bardzo :]

Jak powiązać RadioGroup z Memo

Slowik86

flowCRANE

Slowik86

flowCRANE

Slowik86

flowCRANE

Slowik86

flowCRANE

Slowik86

flowCRANE

Slowik86

flowCRANE

prokopnik

PHP + Codeigniter 4 programista, aplikacja do fakturowania

DevOps Engineer - migracja serwerów (Kubernetes,Docker,RoR)

Programista Systemów Automatyki - PCS7

Praca dla programistów

Forum dyskusyjne

Sprawy administracyjne

O nas

Skontaktuj się z nami