Problem z programem w Pascalu

program zadanie_domowe; 

uses 
  Crt; 

var 
  dane: text; 
  a, b, c: integer; 
  v, pp: real; 
  figura: string; 

begin 
  assign(dane, 'dane.txt'); 
  reset(dane); 
  readln(dane, figura); 
  readln(dane, a); 
  readln(dane, b); 
  readln(dane, c); 
  Close(dane); 

  if figura = 'walec' then 

    begin 
      v:= 3.14*(b*b)*a; 
      pp:= 2*3.14*b*(b+a); 

      writeln('Dane walca to: '); 
      writeln('- wysokość: ', a); 
      writeln('- promień podstawy: ', b); 
      writeln('=========================================='); 
      writeln('Objętość walca wynosi: ', v); 
      writeln('=========================================='); 
      writeln; 
      writeln('=========================================='); 
      writeln('Pole powierzchni walca wynosi: ', pp); 
      writeln('=========================================='); 
    end; 

  readkey; 

end.

walec 
6 
2 

UWAGA! Dane wpisujemy w postaci: 
NAZWA FIGURY 
WYSOKOŚĆ 
PROMIEŃ PODSTAWY

assign(dane, 'dane.txt'); 
reset(dane); 
readln(dane, figura); 
readln(dane, a); 
readln(dane, b); 
readln(dane, c); 
Close(dane);

program Fgr;
uses
  Crt;
const
  PI = 3.14;
  { WALEC }
  ROLLER_RADIUS = 0;
  ROLLER_HEIGHT = 1;
var
  { DANE FIGURY }
  fFigureData: Text;
  sFigureName: String;
  aFigureProps: array of Word;
var
  { WYNIKI }
  rBase, rVolume: Real;
begin
  ClrScr;
  SetLength(aFigureProps, 0);

  Assign(fFigureData, 'C:\Dane.txt');
  Reset(fFigureData);

  if not EoF(fFigureData) then
    begin
      { NAZWA FIGURY }
      ReadLn(fFigureData, sFigureName);

      { DANE POTRZEBNE DO OBLICZEN }
      while not EoF(fFigureData) do
        begin
          SetLength(aFigureProps, Length(aFigureProps) + 1);
          ReadLn(fFigureData, aFigureProps[High(aFigureProps)]);
        end;

      { ROZPOZNANIE FIGURY }
      if sFigureName = 'walec' then
        if Length(aFigureProps) >= 2 then
          begin
            { OBLICZENIA }
            rBase := PI * Sqr(aFigureProps[ROLLER_RADIUS]);
            rVolume := rBase * aFigureProps[ROLLER_HEIGHT];

            { WYSWIETLENIE WYNIKSOW }
            WriteLn('Walec - obliczenia:'#10);
            WriteLn('Pole podstawy: ', rBase:5:2);
            Write('Objętość: ', rVolume:5:2);
          end
        else
          Write('Zbyt mało danych do obliczeń!');
    end
  else
    Write('Plik jest pusty!');

  Close(fFigureData);
  ReadLn;
end.

program zadanie_domowe;

uses
  Crt;

var
  dane, wynik: text;
  a, b, c: integer;
  v, pp: real;
  figura: string;

begin
  assign(dane, 'dane.txt');
  rewrite(dane);
  readln(dane, figura);
  readln(dane, a);
  readln(dane, b);
  readln(dane, c);

  assign(wynik, 'wynik.txt');
  rewrite(wynik);

  if figura = 'walec' then
    begin
      v:= PI*(b*b)*a;
      pp:= 2*PI*b*(b+a);

      writeln('Dane walca to: ');
      writeln('- wysokość: ', a);
      writeln('- promień podstawy: ', b);
      writeln;
      writeln('==========================================');
      writeln('Objętość walca wynosi: ', v);
      writeln('==========================================');
      writeln;
      writeln('==========================================');
      writeln('Pole powierzchni walca wynosi: ', pp);
      writeln('==========================================');
    end;

  if figura = 'prostopadloscian' then
    begin
      v:= a*b*c;
      pp:= 2*(b*c)+2*(a*c)*2*(a*b);

      writeln('Dane prostopadloscianu to: ');
      writeln('- wysokość: ', a);
      writeln('- podstawa - bok a: ', b);
      writeln('- podstawa - bok b: ', c);
      writeln;
      writeln('==========================================');
      writeln('Objętość prostopadłościanu wynosi: ', v);
      writeln('==========================================');
      writeln;
      writeln('==========================================');
      writeln('Pole powierzchni prostopadłościanu wynosi: ', pp);
      writeln('==========================================');
    end;

  if figura = 'stozek' then
    begin
      v:= 1/3*PI*(b*b)*a;
      pp:= PI*b*(b*c);

      writeln('Dane stozka to: ');
      writeln('- wysokość: ', a);
      writeln('- promień podstawy: ', b);
      writeln('- tworząca stożka: ', c);
      writeln;
      writeln('==========================================');
      writeln('Objętość stożka wynosi: ', v);
      writeln('==========================================');
      writeln;
      writeln('==========================================');
      writeln('Pole powierzchni stożka wynosi: ', pp);
      writeln('==========================================');
    end;

  writeln(wynik,v);
  writeln(wynik,pp);

  Close(dane);
  Close(wynik);
  readkey;
end.

program Blocks;
uses
  Crt,
  SysUtils;
const
  PI = 3.14;
const
  { WALEC }
  ROLLER_RADIUS = 0;
  ROLLER_HEIGHT = 1;
const
  { PROSTOPADLOSCIAN }
  CUBOID_BASE_WIDTH  = 0;
  CUBOID_BASE_LENGTH = 1;
  CUBOID_HEIGHT      = 2;
const
  { STOZEK }
  CONE_RADIUS  = 0;
  CONE_HEIGHT  = 1;
var
  { DANE BRYLY }
  fBlockData: Text;
  sInputFileName, sBlockName, sNumber: String;
  aBlockProps: array of Integer;
  iNumber: LongInt;
var
  { WYNIKI }
  rBase, rSurface, rVolume, rForming: Real;
begin
  ClrScr;
  sInputFileName := 'C:\Dane.txt';  

  { ISTNIENIE PLIKU }
  if not FileExists(sInputFileName) then
    begin
      Write('Plik "', sInputFileName, '" nie istnieje!');
      ReadLn;
      Halt;
    end;

  { ODCZYT DANYCH }
  Assign(fBlockData, sInputFileName);
  Reset(fBlockData);
  SetLength(aBlockProps, 0);

  if not EoF(fBlockData) then
    begin
      { NAZWA FIGURY }
      ReadLn(fBlockData, sBlockName);
      sBlockName := UpperCase(sBlockName);

      { DANE POTRZEBNE DO OBLICZEN }
      while not EoF(fBlockData) do
        begin
          ReadLn(fBlockData, sNumber);
          SetLength(aBlockProps, Length(aBlockProps) + 1);

          if TryStrToInt(sNumber, iNumber) and (iNumber > 0) then
            aBlockProps[High(aBlockProps)] := iNumber
          else
            begin
              Write('Wczytano niewlasciwa wartosc!');
              ReadLn;
              Halt;
            end;
        end;

      { WALEC }
      if sBlockName = 'WALEC' then
        begin
          if Length(aBlockProps) >= 2 then
            begin
              { OBLICZENIA }
              rBase := PI * Sqr(aBlockProps[ROLLER_RADIUS]);
              rSurface := rBase * 2 + 2 * PI * Sqr(aBlockProps[ROLLER_HEIGHT]);
              rVolume := rBase * aBlockProps[ROLLER_HEIGHT];
              { WYNIKI }
              WriteLn('Walec - obliczenia'#10);
              WriteLn('Promien podstawy: ', aBlockProps[ROLLER_RADIUS]);
              WriteLn('Wysokosc:         ', aBlockProps[ROLLER_HEIGHT]);
              WriteLn('Pole powierzchni: ', rSurface:5:2);
              Write('Objetosc:         ', rVolume:5:2);
            end
          else
            Write('Zbyt malo danych do obliczen dla walca!');
        end
      else
        { PROSTOPADLOSCIAN }
        if sBlockName = 'PROSTOPADLOSCIAN' then
          begin
            if Length(aBlockProps) >= 3 then
              begin
                { OBLICZENIA }
                rBase := aBlockProps[CUBOID_BASE_WIDTH] *
                         aBlockProps[CUBOID_BASE_LENGTH];
                rSurface := rBase * 2 + 2 * aBlockProps[CUBOID_BASE_WIDTH] *
                            aBlockProps[CUBOID_HEIGHT] + 2 *
                            aBlockProps[CUBOID_BASE_LENGTH] *
                            aBlockProps[CUBOID_HEIGHT];
                rVolume := rBase * aBlockProps[CUBOID_HEIGHT];
                { WYNIKI }
                WriteLn('Prostopadloscian - obliczenia'#10);
                WriteLn('Szerokosc podstawy: ', aBlockProps[CUBOID_BASE_WIDTH]);
                WriteLn('Dlugosc podstawy:   ', aBlockProps[CUBOID_BASE_LENGTH]);
                WriteLn('Wysokosc bryly:     ', aBlockProps[CUBOID_HEIGHT]);
                WriteLn('Pole powierzchni:   ', rSurface:5:2);
                Write('Objetosc:           ', rVolume:5:2);
              end
            else
              Write('Zbyt malo danych do obliczen dla prostopadloscianu!');
            end
          else
            { STOZEK }
            if sBlockName = 'STOZEK' then
              begin
                if Length(aBlockProps) >= 2 then
                  begin
                    { OBLICZENIA }
                    rBase := PI * Sqr(aBlockProps[CONE_RADIUS]);
                    rForming := Sqrt(Sqr(aBlockProps[CONE_RADIUS]) +
                                Sqr(aBlockProps[CONE_HEIGHT]));
                    rSurface := rBase + PI * aBlockProps[CONE_RADIUS] * rForming;
                    rVolume := rBase * aBlockProps[CONE_HEIGHT] / 3;
                    { WYNIKI }
                    WriteLn('Stozek - obliczenia'#10);
                    WriteLn('Promien podstawy: ', aBlockProps[CONE_RADIUS]);
                    WriteLn('Wysokosc:         ', aBlockProps[CONE_HEIGHT]);
                    WriteLn('Tworzaca:         ', rForming:5:2);
                    WriteLn('Pole powierzchni: ', rSurface:5:2);
                    Write('Objetosc:         ', rVolume:5:2);
                  end
                else
                  Write('Zbyt malo danych do obliczen dla stozka!');
              end
            else
              Write('Brak obslugi bryly o nazwie "', sBlockName, '" !');
    end
  else
    Write('Plik jest pusty!');

  Close(fBlockData);
  ReadLn;
end.