Dodanie rekordów do dynamicznej tabeli

My Razem napisał(a):

Mam taki dziwny problem. Liczę że ktoś mi to wytłumaczy czemu się tak dzieje

Za mało kodu podałeś, więc można jedynie zgadywać.

Kopiuj

var  aResult, FinalResult:  arrayOfOXERPType;  <-- to tablica rekordów ale to nieistotnie

To bardzo istotne – pokaż deklarację tej macierzy.

Najpierw z bazy wyciągam jakieś rekordy i wrzucam je do tabeli FinalResult

Do tablicy czy tabeli? Zdecyduj się.

AppendArray(aResult,FinalResult)

Jak inicjalizowana jest macierz FinalResult i jakie dane zawiera w momencie wywołania tej procedury?

Kopiuj

procedure AppendArray(Source: ArrayOfOXERPType; var Dest: ArrayOfOXERPType);

Macierze powinno się przekazywać przez referencję, a Twój Source zawiera kopię tablicy przekazanej w miejscu wywołania (przekazujesz macierz przez wartość). Macierze służące wyłącznie do odczytu przekazuje się przez const, te tylko do zapisu przez out, a do odczytu i zapisu ze słówkiem var. Działa to szybciej, podobnie jak w przypadku przekazywania ciągów znaków czy struktur.

Poza tym ta procedura jest zbędna – do złączenia dwóch dynamicznych macierzy możesz użyć System.Concat.

to w tym momencie z tabeli FinalResult zawsze znika pierwszy element. Zauważcie że teraz jeszcze nie wywołałem procedury AppendArray

Nie wiemy co było w macierzy FinalResult przed wywołaniem AppendArray.

A tak w ogóle to dlaczego nie użyjesz generycznych list rekordów? Miałbyś o wiele mniej roboty, bo wypełenie takiej listy czy dopisanie do niej danych wykonuje się czytelnymi metodami. Zastanów się nad tym.

sprawdź czy w w opcjach kompilacji projektu masz włączone Range checking

Kopiuj

var  aResult, FinalResult:  arrayOfOXERPType;  <-- to tablica rekordów ale to nieistotnie

tutaj źle napisałem - to nie tablica rekordów tylko obiektów

OXERPType = class(TRemotable)
  private
    FaResult: ArrayOfArrayOfString;
    FaResult_Specified: boolean;
    FblResult: Boolean;
    FsMessage: string;
    FsMessage_Specified: boolean;
    procedure SetaResult(Index: Integer; const AArrayOfArrayOfString: ArrayOfArrayOfString);
    function  aResult_Specified(Index: Integer): boolean;
    procedure SetsMessage(Index: Integer; const Astring: string);
    function  sMessage_Specified(Index: Integer): boolean;
  published
    property aResult:  ArrayOfArrayOfString  Index (IS_OPTN) read FaResult write SetaResult stored aResult_Specified;
    property blResult: Boolean               read FblResult write FblResult;
    property sMessage: string                Index (IS_OPTN) read FsMessage write SetsMessage stored sMessage_Specified;
  end;

  ArrayOfOXERPType = array of OXERPType; 

To bardzo istotne – pokaż deklarację tej macierzy.

Najpierw z bazy wyciągam jakieś rekordy i wrzucam je do tabeli FinalResult

Do tablicy czy tabeli? Zdecyduj się.

Oczywiści do tablicy
Moja funkcja zwraca ArrayOfOXERPType więc podstawiam do bezpośrednio do tablicy aResult

AppendArray(aResult,FinalResult)

Jak inicjalizowana jest macierz FinalResult i jakie dane zawiera w momencie wywołania tej procedury?

tablica FinalResult nie jest wcale inicjowana - na początku jest pusta (chociaż sprawdzałem SetLength(FinalResult , 0) ale to nic nie dało)
To taka zmienna pomocnicza do której odkładam rekordy zwrócone z bazy

Kopiuj

procedure AppendArray(Source: ArrayOfOXERPType; var Dest: ArrayOfOXERPType);

Macierze powinno się przekazywać przez referencję, a Twój Source zawiera kopię tablicy przekazanej w miejscu wywołania (przekazujesz macierz przez wartość). Macierze służące wyłącznie do odczytu przekazuje się przez const, te tylko do zapisu przez out, a do odczytu i zapisu ze słówkiem var. Działa to szybciej, podobnie jak w przypadku przekazywania ciągów znaków czy struktur.

Zapewne masz racje ale w moim przypadku ale czy podam const Source czy samo Source zawsze znika pierwszy element w tablicy FinalResult

Poza tym ta procedura jest zbędna – do złączenia dwóch dynamicznych macierzy możesz użyć System.Concat.

Concat mozna używać do łączenia tablic tylko w nowszych wersjach Delphi. Ja mam D2010 i tam to nie działa.

to w tym momencie z tabeli FinalResult zawsze znika pierwszy element. Zauważcie że teraz jeszcze nie wywołałem procedury AppendArray

Nie wiemy co było w macierzy FinalResult przed wywołaniem AppendArray.

Na początku nie było tam nic - pusta tablica

A tak w ogóle to dlaczego nie użyjesz generycznych list rekordów? Miałbyś o wiele mniej roboty, bo wypełenie takiej listy czy dopisanie do niej danych wykonuje się czytelnymi metodami. Zastanów się nad tym.

Podasz przykład?

P.S. Zauważyłem że po przejściu procedury AppendArray moje tablice aResult i FinalResult mają takie same adresy, więc jeśli drugie zapytanie nic nie zwróci więc to "nic" trafia do pierwszej komórki w obu tablicach. Zgadza sie?

przerobiłem moja procedurę AppendArray i teraz tablice maja inne adresy, więc komórki nie są nadpisywane.

procedure AppendArray(const Source: ArrayOfOXERPType; var Dest: ArrayOfOXERPType);
  var
    I, OldLength: Integer;
    Source_OXERPType : OXERPType;
  begin
     OldLength := Length(Dest);
     for I := Low(Source) to High(Source) do
     begin
        Source_OXERPType := OXERPType.Create;
        Source_OXERPType.aResult := Source[I].aResult;
        Source_OXERPType.blResult := Source[I].blResult;
        Source_OXERPType.sMessage := Source[I].sMessage;

        SetLength(Dest, OldLength + Length(Source));
          Dest[I + OldLength] := Source_OXERPType;
     end;

  end;

Czy to jest najlepszy sposób?

My Razem napisał(a):

A tak w ogóle to dlaczego nie użyjesz generycznych list rekordów? Miałbyś o wiele mniej roboty, bo wypełenie takiej listy czy dopisanie do niej danych wykonuje się czytelnymi metodami. Zastanów się nad tym.

Podasz przykład?

Do przechowywania i wygodnego zarządzania obiektami służy generyczna lista TObjectList. Łatwo do niej dodać obiekt (metoda Add), usunąć (metoda Remove lub Extract), posortować itd. Woła się czytelne metody zamiast bawić w alokowanie pamięci. Ustawienie OwnsObjects pozwala włączyć lub wyłączyć automatyczne zwalnianie usuwanych z listy obiektów.

Poczytaj, potestuj – zobaczysz różnicę.

przerobiłem moja procedurę AppendArray i teraz tablice maja inne adresy, więc komórki nie są nadpisywane.
[…]
Czy to jest najlepszy sposób?

To nie jest najlepszy sposób, bo to nie jest poprawny sposób. Dlaczego zmieniasz rozmiar tablicy Dest w pętli? Zrób to raz, przed pętlą, a w niej tylko przepisuj referencje.

Twój problem polega(ł) na tym, że w dwóch listach przechowujesz referencje tych samych obiektów, więc jeśli np. w jednej liście zmodyfikujesz dane obiektu, to w drugiej te dane też będą zmodyfikowane. Jeśli zwolnisz obiekt z jednej listy, to w drugiej adres będzie wskazywać na obszar już zwolniony (czyli na śmieci w pamięci), co może wykrzaczyć program.

Przy czym gdyby Twoja klasa OXERPType dziedziczyła z TPersistent, to mógłbyś wygodnie klonować obiekty po prostu wołając metodę Assign, zamiast ręcznie przepisywać wartości właściwości. Ewentualnie dodaj sobie do tej klasy funkcyjną metodę np. o nazwie Clone, która zajmie się takim przepisywaniem:

type
  OXERPType = class(TRemotable)
  {..}
  public
    function Clone(): OXERPType;
  end;

  function OXERPType.Clone(): OXERPType;
  begin
    Result := OXERPType.Create();
    
    Result.FaResult := Self.FaResult;
    Result.FaResult_Specified := Self.FaResult_Specified;
    Result.FblResult := Self.FblResult;
    
    {..}
  end;

Dzięki temu z zewnątrz będzie ją można wywołać w taki sposób:

procedure AppendArray(const ASource: ArrayOfOXERPType; var ADest: ArrayOfOXERPType);
var
  SourceLen, DestLen, I: Integer;
begin
  SourceLen := Length(ASource);
  
  if SourceLen > 0 then
  begin
    DestLen := Length(ADest);
    SetLength(ADest, DestLen + SourceLen);
    
    for I := Low(ASource) to High(ASource) do
      ADest[DestLen + I] := ASource[I].Clone();
  end;
end;

Choć gdybym koniecznie musiał używać tablic dynamicznych, to bym sobie do typu macierzy dodał metody i właściwości za pomocą helperów, coby rąk nie brudzić tym Low, High, SetLength itd. Ale nie wiem czy Twoje Delphi na to pozwala.