Standardowe kontrolki, Ctrl+BkSp i usuwanie poprzedniego wyrazu

Standardowe kontrolki, Ctrl+BkSp i usuwanie poprzedniego wyrazu
flowCRANE
flowCRANE
flowCRANE
flowCRANE
Moderator Delphi/Pascal
  • Rejestracja:ponad 13 lat
  • Ostatnio:około 9 godzin
  • Lokalizacja:Tuchów
  • Postów:12164
0

Potrzebuję zaimplementować w standardowych kontrolkach (głównie TMemo i TEdit/TLabeledEdit) usuwanie poprzedniego wyrazu za pomocą kombinacji Ctrl + BkSp tak, jak ma to miejsce np. w edytorze kodu w Delphi 7;

Kombinowałem już ze zdarzeniami OnKeyDown, OnKeyUp i OnKeyPress zarówno kontrolki jak i formularza, z włączonym i wyłączonym KeyPreview formularza rodzica, niestety bez powodzenia; Bez względu na powyższe ustawienia w danej kontrolce i tak zostaje wpisany kwadracik, mimo zerowania argumentu Key we wszystkich zdarzeniach; Próbowałem także wykorzystać prywatną zmienną typu Boolean - ustawiałem na True w zdarzeniu OnKeyDown jeśli ssCtrl został wciśnięty (ssCtrl in Shift), oraz na False w OnKeyUp gdy został puszczony (ssCtrl in Shift) po to, bym mógł sprawdzić stan tego specialnego klawisza w zdarzeniu OnKeyPress, jednak także bez powodzenia; Niestety zawsze, gdy wykombinuję Ctrl + BkSp do kontrolki zostaje wpisany kwadracik;

Pośrednio można to rozwiązać przez dodanie do menu głównego nową pozycję typu Usuń poprzedni wyraz i ustawiając jej HotKey na Ctrl+BkSp, jednak wolałbym tego nie robić (choć w ostateczności przymknę okno); W każdym formularzu, gdzie istnieją kontrolki klas TMemo czy TEdit/TLabeledEdit zarówno w menu głownych jak i kontekstowych jest odpowiednia sekcja Edycja i mógłbym tam dodać taką pozycję, jednak wolałbym te menu pozostawić bez zmian, gdyż ich rozbudowa zahaczałaby pod modyfikację własnych paczek ikon i większe przeróbki; To oczywiście nie jest żaden problem, ale takie modyfikacje pochłaniają czas, który wolałbym przeznaczyć na rozbudowę innych elementów programu;

W sieci znalazłem mnóstwo artykułów na temat blokowania klawiszy VK_BACK czy VK_DELETE (co już stosowałem dawno temu), ale w połączeniu z Ctrl nie sprawdzą się;

To ile znaków i dokąd odbędzie się usuwanie jeszcze nie określiłem dokładnie, na razie testowałem z usuwaniem ciągu znaków do znaku ' ' (spacji), ale nie udało się;

Czy ktokolwiek wie w jaki sposób można osiągnąć taki efekt? Jak usunąć poprzedni wyraz do jakiegokolwiek znaku? Będę bardzo wdzięczny za wskazówki;

Pracuję nad własną, arcade'ową, docelowo komercyjną grą z gatunku action/adventure w stylu retro (pixel art), programując silnik i powłokę gry od zupełnych podstaw, przy użyciu Free Pascala i SDL3. Więcej informacji znajdziesz na moim mikroblogu.
edytowany 2x, ostatnio: flowCRANE
Udostępnij
Kopiuj link do postu Kopiuj link do postu jako Markdown
Komentuj
kAzek
KA
kAzek
KA
  • Rejestracja:prawie 20 lat
  • Ostatnio:2 minuty
  • Lokalizacja:Gorlice
3

Tak na szybko wymyśliłem coś takiego:

Kopiuj
procedure TForm1.OnMsg(var Msg: TMsg; var Handled: Boolean);
var
  ctrl: TWinControl;
  len, i: Integer;
  buff: string;
begin
  if Msg.message = WM_KEYDOWN then
  begin
    //czy ctrl + backspace wcisniety?
    if (Msg.wParam = VK_BACK) and (GetKeyState(VK_CONTROL) and 128 = 128) then
    begin
      ctrl:= Screen.ActiveControl; //aktywna kontrolka
      //czy o taka nam chodzi?
      if Assigned(ctrl) and ((ctrl is TEdit) or (ctrl is TMemo) or (ctrl is TLabeledEdit)) then
      begin
        len:= GetWindowTextLength(Msg.hwnd);  //pobierz dlugosc tekstu
        SetLength(buff, len);  //ustaw wielkosc buffera
        GetWindowText(Msg.hwnd, PChar(buff), len + 1); //pobierz tekst
        //usun spacje i znaki konca wiersza na koncu tekstu
        while (Length(buff) > 0) and ((buff[Length(buff)] = #32) or
          (buff[Length(buff)] = #13) or (buff[Length(buff)] = #10)) do
          SetLength(buff, Length(buff) - 1);
        for i:=Length(buff) downto 1 do //usuwaj znaki do napotkania spacji lub konca wiersza
        begin
          if (buff[i] = #32) or (buff[i] = #13) or (buff[i] = #10) then
            break;
          SetLength(buff, Length(buff) - 1);
        end;
        //usun spacje i znaki konca wiersza na koncu tekstu
        while (Length(buff) > 0) and ((buff[Length(buff)] = #32) or
          (buff[Length(buff)] = #13) or (buff[Length(buff)] = #10)) do
          SetLength(buff, Length(buff) - 1);
        SetWindowText(Msg.hwnd, PChar(buff)); //zmien tekst
        SendMessage(Msg.hwnd, EM_SETSEL, Length(buff), Length(buff)); //ustaw kursor na koncu tekstu
        Handled:= True; //komunikat zostal obsluzony
      end;
    end;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.OnMessage:= OnMsg;
end;

Użyłem funkcji WinApi aby kod był jak najbardziej uniwersalny TWinControl nie ma właściwości Text i trzeba by sprawdzać za każdym razem (lub pisać osobny kod dla każdego rodzaju kontrolki) i odpowiednio rzutować a tu masz wszystkie te kontrolki (działało by też z TRichEdit) za jednym zamachem.

Nie odpowiadam na PW w sprawie pomocy programistycznej.
Pytania zadawaj na forum, bo:
od tego ono jest ;) | celowo nie zawracasz gitary | przeczyta to więcej osób a więc większe szanse że ktoś pomoże.
edytowany 5x, ostatnio: kAzek
Udostępnij
Kopiuj link do postu Kopiuj link do postu jako Markdown
Komentuj
flowCRANE
flowCRANE
flowCRANE
flowCRANE
Moderator Delphi/Pascal
  • Rejestracja:ponad 13 lat
  • Ostatnio:około 9 godzin
  • Lokalizacja:Tuchów
  • Postów:12164
0

Nie ma to jak powrót do WinAPI :]

Kod dopiero co przetestowałem i fakt, komunikat zostaje poprawnie obsłużony, jednak nie do końca chodziło mi o taki efekt; W Twoim kodzie @kAzek usuwany jest zawsze ostatni wyraz ciągu bez względu na to gdzie znajduje się kursor w TMemo, ale nic nie stoi na przeszkodzie aby go troszkę przerobić - to nic trudnego; Wystarczyło jedynie dowiedzieć się, że trzeba się podpiąć pod zdarzenie OnMessage i po obsłudze danego komunikatu ustawić Handled, by po raz kolejny go nie przetwarzano; Dziś się tym pobawię i jak skończę to udostępnię gotowy kod do testowania;

Dziękuję jeszcze raz, pozdrawiam;

Edit

Podaję kod, który realizuje zadanie usuwania wyrazu z lewej strony kursora w kontrolkach klas TMemo i TEdit:

Kopiuj
procedure TMainForm.OnMessage(var AMsg: TMsg; var AHandled: Boolean);
const
  STOP_CHARS_ARR = [#10, #13, #32, #33, #40, #41, #44, #45, #46, 
                    #47, #63, #91, #92, #93, #123, #124, #125];
var
  ctrlActive: TWinControl;
  iCaretPos, iLength: Integer;
  sLeft, sRight: String;
begin
  if AMsg.message = WM_KEYDOWN then
    if (AMsg.wParam = VK_BACK) and (GetKeyState(VK_CONTROL) and 128 = 128) then
      begin
        ctrlActive := Screen.ActiveControl;

        if Assigned(ctrlActive) and ((ctrlActive is TMemo) or (ctrlActive is TEdit)) then
          begin
            iLength := GetWindowTextLength(AMsg.hWnd);
            iCaretPos := LoWord(SendMessage(AMsg.hWnd, EM_GETSEL, 0, 0));

            SetLength(sLeft, iLength);
            GetWindowText(AMsg.hWnd, PChar(sLeft), Succ(iLength));
            sRight := Copy(sLeft, Succ(iCaretPos), iLength - iCaretPos);
            SetLength(sLeft, iCaretPos);

            while (Length(sLeft) > 0) and (sLeft[Length(sLeft)] in STOP_CHARS_ARR) do
              SetLength(sLeft, Pred(Length(sLeft)));

            while (Length(sLeft) > 0) and not (sLeft[Length(sLeft)] in STOP_CHARS_ARR) do
              SetLength(sLeft, Pred(Length(sLeft)));

            while (Length(sLeft) > 0) and (sLeft[Length(sLeft)] in [#10, #13, #32]) do
              SetLength(sLeft, Pred(Length(sLeft)));

            SetWindowText(AMsg.hWnd, PChar(sLeft + sRight));
            SendMessage(AMsg.hWnd, EM_SETSEL, Length(sLeft), Length(sLeft));
            AHandled := True;
          end;
      end;
end;

Mam jeszcze jedno pytanie odnośnie ww. kodu - jak wiadomo klasa TMemo ma właściwość Modified, której wartość zmienia się na True, jeśli zmieni się zawartość kontrolki; Jeśli ww. kod zostanie wykonany to nie dość, że nie zmienia mi wartości tej właściwości, to jeszcze kasuje bufor cofania (CanUndo na False) i już nie można cofnąć; Czy jest jakiś sposób na ochronienie CanUndo i na zmianę stanu właściwości Modified po wykonaniu powyższego kodu?

Pracuję nad własną, arcade'ową, docelowo komercyjną grą z gatunku action/adventure w stylu retro (pixel art), programując silnik i powłokę gry od zupełnych podstaw, przy użyciu Free Pascala i SDL3. Więcej informacji znajdziesz na moim mikroblogu.
edytowany 3x, ostatnio: flowCRANE
Azarien
"powrót"? zaczynałeś naukę od WinAPI? ;-)
KA
A no o tym nie pomyślałem żeby brać pod uwagę aktualną pozycję kursora ale jak piszesz że już sobie poradzisz to spoko. Cieszę się ze mogłem pomóc.
KA
@Azarien a dlaczego nie ja na początku miałem Borland Pascal chyba 7 jeszcze pirata przyznaję bez bicia a dorwałem go "w spadku" po starszym bracie wtedy studencie i tak się zaczynało a tam było coś pod Windows nie pamiętam jak się nazywało w każdym razie można było pisać pod Windows (oczywiście w wersji 3.X) właśnie w WinApi później za sprawą jakiegoś czasopisma odkryłem Delphi 2 (1 przespałem), jaki Internet nawet jak już miałem nawet możliwość skorzystać to na moment bo rachunki ;) To było czasy nie było nawet tego forum a człowiek umiał korzystać z helpa i kombinować.
flowCRANE
@Azarien, nie zaczynałem od WinAPI tylko od struktoralnych Pascala i C++ (w TI), ale w domu zacząłem naukę WinAPI w C++ i bardzo mi się spodobało, w końcu mogłem tworzyć okienka, przyciski, pola edycyjne itd. :) Ale po niedługim czasie znalazłem w antykwariacie książkę o podstawach Delphi i ucieszył mnie fakt, że nie trzeba pisać potężnych modułów i ręcznie obsługiwać komunikatów; Wtedy jeszcze neta nie miałem - tylko wydrukowaną książkę jakiegoś studenta o podstawach WInAPI, ale mimo wszystko przygodę z WinAPI mile wspominam, choć krótka była :)
Azarien
@kAzek: Borland Pascal 7 zawierał bibliotekę Object Windows, więc już wtedy WinAPI nie było koniecznością :-) a WinAPI to ja właściwie dopiero zaczynam…
Udostępnij
Kopiuj link do postu Kopiuj link do postu jako Markdown
Komentuj
kAzek
KA
kAzek
KA
  • Rejestracja:prawie 20 lat
  • Ostatnio:2 minuty
  • Lokalizacja:Gorlice
1
furious programming napisał(a):

Mam jeszcze jedno pytanie odnośnie ww. kodu - jak wiadomo klasa TMemo ma właściwość Modified, której wartość zmienia się na True, jeśli zmieni się zawartość kontrolki; Jeśli ww. kod zostanie wykonany to nie dość, że nie zmienia mi wartości tej właściwości, to jeszcze kasuje bufor cofania (CanUndo na False) i już nie można cofnąć; Czy jest jakiś sposób na ochronienie CanUndo i na zmianę stanu właściwości Modified po wykonaniu powyższego kodu?

Z tym może być problem bo:
The system automatically resets the undo flag whenever an edit control receives an EM_SETHANDLE or WM_SETTEXT message. a ten komunikat jest wysyłany przy zmianie tekstu przez SetWindowText i SetDlgItemText a więc d... blada i żadne EM_SETMODIFY tu nie pomoże bo bufor i tak jest pusty.

Co mogę zaproponować to "małe oszustwo" jak wiadomo kontrolki typu EDIT (memo to edit tylko z ES_MULTILINE) obsługują komunikaty EM_SETSEL i EM_REPLACESEL a ten drugi pozwala na ustawienie flagi CanUndo w wParam więc zaznaczyć tekst który ma być usunięty przy ctrl + backspace i zmienić na pusty wtedy teoretycznie (bo nie sprawdzałem) powinno wszystko działać jak należy. Myślę że takie programowe zaznaczenie i zmiana zaznaczonego tekstu powinno być na tyle szybkie że nie będzie widoczne dla użyszkodnika więc raczej nic nie stoi na przeszkodzie aby wykorzystać takie rozwiązanie (o ile zadziała bo nie sprawdzałem).

EDIT//
Miałem chwilę czasu i sprawdziłem z tym EM_SETSEL (zaznaczenie tekstu który trzeba wyciąć) i EM_REPLACESEL (zmiana go na pusty czyli wycinanie) działa ale po wykonaniu Cofnij tekst jest zaznaczony więc trochę nie ładnie... ale na razie nie mam innego pomysłu.

Nie odpowiadam na PW w sprawie pomocy programistycznej.
Pytania zadawaj na forum, bo:
od tego ono jest ;) | celowo nie zawracasz gitary | przeczyta to więcej osób a więc większe szanse że ktoś pomoże.
edytowany 1x, ostatnio: kAzek
Udostępnij
Kopiuj link do postu Kopiuj link do postu jako Markdown
Komentuj
flowCRANE
flowCRANE
flowCRANE
flowCRANE
Moderator Delphi/Pascal
  • Rejestracja:ponad 13 lat
  • Ostatnio:około 9 godzin
  • Lokalizacja:Tuchów
  • Postów:12164
0

Podłubałem troszkę przy EM_SETSEL i EM_REPLACESEL i w końcu działa; Poczytałem o tej drugiej fladze i aby dać możliwość cofnięcia trzeba wParam ustawić na True, np. Integer(True) lub po prostu 1;

Działający kod:

Kopiuj
procedure TMainForm.OnMessage(var AMsg: TMsg; var AHandled: Boolean);
const
  STOP_CHARS_ARR = [#10, #13, #32, #33, #40, #41, #44, #45, #46,
                    #47, #63, #91, #92, #93, #123, #124, #125];
var
  ctrlActive: TWinControl;
  iTextLen, iCaretPos, iSelStart: Integer;
  sLeft: String;
begin
  if AMsg.message = WM_KEYDOWN then
    if (AMsg.wParam = VK_BACK) and (GetKeyState(VK_CONTROL) and 128 = 128) then
      begin
        ctrlActive := Screen.ActiveControl;

        if Assigned(ctrlActive) and ((ctrlActive is TMemo) or (ctrlActive is TEdit)) then
          begin
            AHandled := True;

            if (ctrlActive is TEdit) and TEdit(ctrlActive).ReadOnly then
              Exit;

            iTextLen := GetWindowTextLength(AMsg.hWnd);
            iCaretPos := LoWord(SendMessage(AMsg.hWnd, EM_GETSEL, 0, 0));
            SetLength(sLeft, iCaretPos);
            GetWindowText(AMsg.hWnd, PChar(sLeft), iCaretPos);
            iSelStart := iCaretPos;

            while (iSelStart > 0) and (sLeft[iSelStart] in STOP_CHARS_ARR) do
              Dec(iSelStart);

            while (iSelStart > 0) and (not (sLeft[iSelStart] in STOP_CHARS_ARR)) do
              Dec(iSelStart);

            while (iSelStart > 0) and (sLeft[iSelStart] in [#10, #13, #32]) do
              Dec(iSelStart);

            if iSelStart < iCaretPos then
              begin
                SendMessage(AMsg.hWnd, EM_SETSEL, iSelStart, iCaretPos);
                SendMessage(AMsg.hWnd, EM_REPLACESEL, Integer(True), Integer(PChar('')));

                if (GetWindowTextLength(AMsg.hWnd) <> iTextLen) and (ctrlActive.Name = 'memNote') then
                  begin
                    UpdateToolbar();
                    UpdateNoteControls();
                  end;
              end;
          end;
      end;
end;

Procedury UpdateToolbar i UpdateNoteControls odświeżają przyciski na pasku narzędzi i inne kontrolki powiązane z polem opisu w głównym formularzu; Warunek if iSelStart < iCaretPos then jest konieczny, bo jeśli nic nie będzie usuwane to komunikat nie zostanie wysłany i nie zmieni mi właściwości Modified pola na False, a o to mi chodzi;

Dziękuję @kAzek za pomoc, pozdrawiam :]

Pracuję nad własną, arcade'ową, docelowo komercyjną grą z gatunku action/adventure w stylu retro (pixel art), programując silnik i powłokę gry od zupełnych podstaw, przy użyciu Free Pascala i SDL3. Więcej informacji znajdziesz na moim mikroblogu.
edytowany 1x, ostatnio: flowCRANE
Udostępnij
Kopiuj link do postu Kopiuj link do postu jako Markdown
Komentuj
Treść
Podgląd
Kliknij, aby dodać treść...
Kliknij, aby dodać załącznik lub wklej ze schowka.
Instrukcja obsługi Markdown
Pomoc 1.18.8

Typografia

Edytor obsługuje składnie Markdown, w której pojedynczy akcent *kursywa* oraz _kursywa_ to pochylenie. Z kolei podwójny akcent **pogrubienie** oraz __pogrubienie__ to pogrubienie. Dodanie znaczników ~~strike~~ to przekreślenie.

Możesz dodać formatowanie komendami , , oraz .

Ponieważ dekoracja podkreślenia jest przeznaczona na linki, markdown nie zawiera specjalnej składni dla podkreślenia. Dlatego by dodać podkreślenie, użyj <u>underline</u>.

Komendy formatujące reagują na skróty klawiszowe: Ctrl+B, Ctrl+I, Ctrl+U oraz Ctrl+S.

Linki

By dodać link w edytorze użyj komendy lub użyj składni [title](link). URL umieszczony w linku lub nawet URL umieszczony bezpośrednio w tekście będzie aktywny i klikalny.

Jeżeli chcesz, możesz samodzielnie dodać link: <a href="link">title</a>.

Wewnętrzne odnośniki

Możesz umieścić odnośnik do wewnętrznej podstrony, używając następującej składni: [[Delphi/Kompendium]] lub [[Delphi/Kompendium|kliknij, aby przejść do kompendium]]. Odnośniki mogą prowadzić do Forum 4programmers.net lub np. do Kompendium.

Wspomnienia użytkowników

By wspomnieć użytkownika forum, wpisz w formularzu znak @. Zobaczysz okienko samouzupełniające nazwy użytkowników. Samouzupełnienie dobierze odpowiedni format wspomnienia, zależnie od tego czy w nazwie użytkownika znajduje się spacja.

Znaczniki HTML

Dozwolone jest używanie niektórych znaczników HTML: <a>, <b>, <i>, <kbd>, <del>, <strong>, <dfn>, <pre>, <blockquote>, <hr/>, <sub>, <sup> oraz <img/>.

Skróty klawiszowe

Dodaj kombinację klawiszy komendą notacji klawiszy lub skrótem klawiszowym Alt+K.

Reprezentuj kombinacje klawiszowe używając taga <kbd>. Oddziel od siebie klawisze znakiem plus, np <kbd>Alt+Tab</kbd>.

Indeks górny oraz dolny

Przykład: wpisując H<sub>2</sub>O i m<sup>2</sup> otrzymasz: H2O i m2.

Składnia Tex

By precyzyjnie wyrazić działanie matematyczne, użyj składni Tex.

<tex>arcctg(x) = argtan(\frac{1}{x}) = arcsin(\frac{1}{\sqrt{1+x^2}})</tex>

Kod źródłowy

Krótkie fragmenty kodu

Wszelkie jednolinijkowe instrukcje języka programowania powinny być zawarte pomiędzy obróconymi apostrofami: `kod instrukcji` lub ``console.log(`string`);``.

Kod wielolinijkowy

Dodaj fragment kodu komendą . Fragmenty kodu zajmujące całą lub więcej linijek powinny być umieszczone w wielolinijkowym fragmencie kodu. Znaczniki ``` lub ~~~ umożliwiają kolorowanie różnych języków programowania. Możemy nadać nazwę języka programowania używając auto-uzupełnienia, kod został pokolorowany używając konkretnych ustawień kolorowania składni:

```javascript
document.write('Hello World');
```

Możesz zaznaczyć również już wklejony kod w edytorze, i użyć komendy  by zamienić go w kod. Użyj kombinacji Ctrl+`, by dodać fragment kodu bez oznaczników języka.

Tabelki

Dodaj przykładową tabelkę używając komendy . Przykładowa tabelka składa się z dwóch kolumn, nagłówka i jednego wiersza.

Wygeneruj tabelkę na podstawie szablonu. Oddziel komórki separatorem ; lub |, a następnie zaznacz szablonu.

nazwisko;dziedzina;odkrycie
Pitagoras;mathematics;Pythagorean Theorem
Albert Einstein;physics;General Relativity
Marie Curie, Pierre Curie;chemistry;Radium, Polonium

Użyj komendy by zamienić zaznaczony szablon na tabelkę Markdown.

Lista uporządkowana i nieuporządkowana

Możliwe jest tworzenie listy numerowanych oraz wypunktowanych. Wystarczy, że pierwszym znakiem linii będzie * lub - dla listy nieuporządkowanej oraz 1. dla listy uporządkowanej.

Użyj komendy by dodać listę uporządkowaną.

1. Lista numerowana
2. Lista numerowana

Użyj komendy by dodać listę nieuporządkowaną.

* Lista wypunktowana
* Lista wypunktowana
** Lista wypunktowana (drugi poziom)

Składnia Markdown

Edytor obsługuje składnię Markdown, która składa się ze znaków specjalnych. Dostępne komendy, jak formatowanie , dodanie tabelki lub fragmentu kodu są w pewnym sensie świadome otaczającej jej składni, i postarają się unikać uszkodzenia jej.

Dla przykładu, używając tylko dostępnych komend, nie możemy dodać formatowania pogrubienia do kodu wielolinijkowego, albo dodać listy do tabelki - mogłoby to doprowadzić do uszkodzenia składni.

W pewnych odosobnionych przypadkach brak nowej linii przed elementami markdown również mógłby uszkodzić składnie, dlatego edytor dodaje brakujące nowe linie. Dla przykładu, dodanie formatowania pochylenia zaraz po tabelce, mogłoby zostać błędne zinterpretowane, więc edytor doda oddzielającą nową linię pomiędzy tabelką, a pochyleniem.

Skróty klawiszowe

Skróty formatujące, kiedy w edytorze znajduje się pojedynczy kursor, wstawiają sformatowany tekst przykładowy. Jeśli w edytorze znajduje się zaznaczenie (słowo, linijka, paragraf), wtedy zaznaczenie zostaje sformatowane.

  • Ctrl+B - dodaj pogrubienie lub pogrub zaznaczenie
  • Ctrl+I - dodaj pochylenie lub pochyl zaznaczenie
  • Ctrl+U - dodaj podkreślenie lub podkreśl zaznaczenie
  • Ctrl+S - dodaj przekreślenie lub przekreśl zaznaczenie

Notacja Klawiszy

  • Alt+K - dodaj notację klawiszy

Fragment kodu bez oznacznika

  • Alt+C - dodaj pusty fragment kodu

Skróty operujące na kodzie i linijkach:

  • Alt+L - zaznaczenie całej linii
  • Alt+, Alt+ - przeniesienie linijki w której znajduje się kursor w górę/dół.
  • Tab/⌘+] - dodaj wcięcie (wcięcie w prawo)
  • Shit+Tab/⌘+[ - usunięcie wcięcia (wycięcie w lewo)

Dodawanie postów:

  • Ctrl+Enter - dodaj post
  • ⌘+Enter - dodaj post (MacOS)