Grupowanie właściwości :: 4programmers.net

flowCRANE

2011-11-15 15:19

flowCRANE2011-11-15 15:19

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12164

Witam wszystkich, potrzebuję nieco rozbudować komponent TListBox o kilkanaście właściwości, które będą umieszczone w trzech podstawowych grupach; Jak na razie próbuję zrobić pierwszą grupę, ale coś mi nie wychodzi...

Potrzebuję, by na liście w ObjectInspector pojawiła się grupa Colors, w której znajdować się będą takie właściwości:

Text
TextActive
Back
BackActive
DotsLine
Wszystkie te właściwości mają przechowywać kolor (czyli typ TColor); Grupa ma się nazywać Colors;

Sugerowałem się artykułami z 4p:
http://4programmers.net/Delphi/ARtykuły/Jak_korzystać_z_TPersistent
i ze strony FlyLib:
http://flylib.com/books/en/1.228.1.154/1/

niestety grupa się pokazuje, ale nie chce się rozwijać... Grzebię w tym już od południa i dalej nie wiem, co jest źle, kod poniżej:

Kopiuj

unit FldListBox;

interface

uses
  SysUtils,
  Classes,
  Controls,
  StdCtrls,
  Graphics;

type
  TFoldersListBoxColors = class(TPersistent)
  private
    FText: TColor;
    FTextActive: TColor;
    FBack: TColor;
    FBackActive: TColor;
    FDotsLine: TColor;
  published
    property Text: TColor read FText write FText;
    property TextActive: TColor read FTextActive write FTextActive;
    property Back: TColor read FBack write FBack;
    property BackActive: TColor read FBackActive write FBackActive;
    property DotsLine: TColor read FDotsLine write FDotsLine;
  end;

type
  TFoldersListBox = class(TListBox)
  private
    FColors: TFoldersListBoxColors;
  public
    {$WARNINGS OFF}
    constructor Create(AOwner: TComponent);
    destructor Destroy(); override;
    {$WARNINGS ON}
  published
    property Colors: TFoldersListBoxColors read FColors write FColors;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('pnggc', [TFoldersListBox]);
end;

constructor TFoldersListBox.Create(AOwner: TComponent);
begin
  inherited Create(Aowner);
  FColors := TFoldersListBoxColors.Create();

  with FColors do
    begin
      FText := clBlack;
      FTextActive := clWhite;
      FBack := clWhite;
      FBackActive := clMenuHighlight;
      FDotsLine := clGray;
    end;
end;

destructor TFoldersListBox.Destroy();
begin
  FColors.Free();
  inherited Destroy();
end;

end.

Moduł się oczywiście kompiluje, w programie 'kładąc' komponent na formie też nie wyskakują żadne błędy, program też się kompiluje i działa bez zarzutu, usuwać - też się usuwa z pamięci bezproblemowo;

Moje pytanie brzmi - co jeszcze mam zrobić by klasa działała jak należy?

edytowany 1x, ostatnio: flowCRANE 2011-11-15 15:19

cimak 2011-11-15 15:33

czy create nie powinno tez byc override?

flowCRANE 2011-11-15 15:44

..... ale ze mnie matoł, no pewnie, że powinno być :P

cimak 2011-11-15 15:53

teraz dziala?:)

flowCRANE 2011-11-15 16:01

działa, działa :) dopiero zaczną się pewnie kłopoty, jak będę robił grupę przechowującą ikony :P Jakby coś się działo złego - napiszę jeszcze;

flowCRANE

2011-11-15 16:26

flowCRANE2011-11-15 16:26

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12164

No nic, uporałem się w końcu z tym; Poniżej zamieszczam kod modułu, który działa w 100%:

Kopiuj

unit FldListBox;

interface

uses
  SysUtils,
  Classes,
  Controls,
  StdCtrls,
  Graphics;

type
  TFoldersListBoxIcons = class(TPersistent)
  private
    FPlus: TIcon;
    FMinus: TIcon;
    FDesktop: TIcon;
    FMyDocs: TIcon;
    FHardDrive: TIcon;
    FCDRom: TIcon;
    FFolder: TIcon;
  protected
    procedure SetPlus(Value: TIcon);
    procedure SetMinus(Value: TIcon);
    procedure SetDesktop(Value: TIcon);
    procedure SetMyDocs(Value: TIcon);
    procedure SetHardDrive(Value: TIcon);
    procedure SetCDRom(Value: TIcon);
    procedure SetFolder(Value: TIcon);
  public
    constructor Create();
    destructor Destroy(); override;
  published
    property Plus: TIcon read FPlus write SetPlus;
    property Minus: TIcon read FMinus write SetMinus;
    property Desktop: TIcon read FDesktop write SetDesktop;
    property MyDocs: TIcon read FMyDocs write SetMyDocs;
    property HardDrive: TIcon read FHardDrive write SetHardDrive;
    property CDRom: TIcon read FCDRom write SetCDRom;
    property Folder: TIcon read FFolder write SetFolder;
  end;

type
  TFoldersListBoxColors = class(TPersistent)
  private
    FText: TColor;
    FTextActive: TColor;
    FBack: TColor;
    FBackActive: TColor;
    FDotsLine: TColor;
  published
    property Text: TColor read FText write FText;
    property TextActive: TColor read FTextActive write FTextActive;
    property Back: TColor read FBack write FBack;
    property BackActive: TColor read FBackActive write FBackActive;
    property DotsLine: TColor read FDotsLine write FDotsLine;
  end;

type
  TFoldersListBoxOffsets = class(TPersistent)
  private
    FSubItem: Byte;
    FButton: Byte;
    FIcon: Byte;
    FText: Byte;
  published
    property SubItem: Byte read FSubItem write FSubItem;
    property Button: Byte read FButton write FButton;
    property Icon: Byte read FIcon write FIcon;
    property Text: Byte read FText write FText;
  end;

type
  TFoldersListBoxGroups = class(TPersistent)
  private
    FIcons: TFoldersListBoxIcons;
    FColors: TFoldersListBoxColors;
    FOffsets: TFoldersListBoxOffsets;
  published
    procedure SetIcons(Value: TFoldersListBoxIcons);
    procedure SetColors(Value: TFoldersListBoxColors);
    procedure SetOffsets(Value: TFoldersListBoxOffsets);
  public
    constructor Create();
    destructor Destroy(); override;
  published
    property Icons: TFoldersListBoxIcons read FIcons write SetIcons;
    property Colors: TFoldersListBoxColors read FColors write SetColors;
    property Offsets: TFoldersListBoxOffsets read FOffsets write SetOffsets;
  end;

type
  TFoldersListBox = class(TListBox)
  private
    FGroups: TFoldersListBoxGroups;
  protected
    procedure SetGroups(Value: TFoldersListBoxGroups);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy(); override;
  published
    property Tree: TFoldersListBoxGroups read FGroups write SetGroups;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('pnggc', [TFoldersListBox]);
end;



constructor TFoldersListBoxIcons.Create();
begin
  inherited Create();

  FPlus := TIcon.Create();
  FMinus := TIcon.Create();
  FDesktop := TIcon.Create();
  FMyDocs := TIcon.Create();
  FHardDrive := TIcon.Create();
  FCDRom := TIcon.Create();
  FFolder := TIcon.Create();
end;

destructor TFoldersListBoxIcons.Destroy();
begin
  FPlus.Free();
  FMinus.Free();
  FDesktop.Free();
  FMyDocs.Free();
  FHardDrive.Free();
  FCDRom.Free();
  FFolder.Free();

  inherited Destroy();
end;

procedure TFoldersListBoxIcons.SetPlus(Value: TIcon);
begin
  FPlus.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetMinus(Value: TIcon);
begin
  FMinus.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetDesktop(Value: TIcon);
begin
  FDesktop.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetMyDocs(Value: TIcon);
begin
  FMyDocs.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetHardDrive(Value: TIcon);
begin
  FHardDrive.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetCDRom(Value: TIcon);
begin
  FCDRom.Assign(Value);
end;

procedure TFoldersListBoxIcons.SetFolder(Value: TIcon);
begin
  FFolder.Assign(Value);
end;



constructor TFoldersListBoxGroups.Create();
begin
  inherited Create();

  FIcons := TFoldersListBoxIcons.Create();

  FColors := TFoldersListBoxColors.Create();

  with FColors do
    begin
      FText := clBlack;
      FTextActive := clWhite;
      FBack := clWhite;
      FBackActive := clMenuHighlight;
      FDotsLine := clGray;
    end;

  FOffsets := TFoldersListBoxOffsets.Create();

  with FOffsets do
    begin
      FSubItem := 0;
      FButton := 0;
      FIcon := 0;
      FText := 0;
    end;
end;

destructor TFoldersListBoxGroups.Destroy();
begin
  FIcons.Free();
  FColors.Free();
  FOffsets.Free();

  inherited Destroy();
end;

procedure TFoldersListBoxGroups.SetIcons(Value: TFoldersListBoxIcons);
begin
  FIcons.Assign(Value);
end;

procedure TFoldersListBoxGroups.SetColors(Value: TFoldersListBoxColors);
begin
  FColors.Assign(Value);
end;

procedure TFoldersListBoxGroups.SetOffsets(Value: TFoldersListBoxOffsets);
begin
  FOffsets.Assign(Value);
end;



constructor TFoldersListBox.Create(AOwner: TComponent);
begin
  inherited Create(Aowner);

  FGroups := TFoldersListBoxGroups.Create();
end;

destructor TFoldersListBox.Destroy();
begin
  FGroups.Free();

  inherited Destroy();
end;

procedure TFoldersListBox.SetGroups(Value: TFoldersListBoxGroups);
begin
  FGroups.Assign(Value);
end;

end.

co daje efekt:

Kod udostępniam, bo może się komuś jeszcze przydać (Można na jego podstawie rozwinąć artykuł na tym forum odnoście używania klasy TPersistent); Pozdrawiam;

GroupedProps.png (9 KB) - ściągnięć: 172

edytowany 3x, ostatnio: flowCRANE 2011-11-15 16:49

flowCRANE

2011-11-16 09:45

flowCRANE2011-11-16 09:45

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12164

EDIT: Piszę nowy post, bo powyższy jest strasznie długi...

Mam jeszcze pytanie odnośnie deklarowania procedur do ładowania ikon; W jaki sposób mogę skrócić ten kod:

Kopiuj

type
  TFoldersListBoxIcons = class(TPersistent)
  private
    FPlus,
    FMinus,
    FDesktop,
    FMyDocs,
    FHardDrive,
    FCDRom,
    FFolder: TIcon;
  protected
    procedure SetPlus(Value: TIcon);
    procedure SetMinus(Value: TIcon);
    procedure SetDesktop(Value: TIcon);
    procedure SetMyDocs(Value: TIcon);
    procedure SetHardDrive(Value: TIcon);
    procedure SetCDRom(Value: TIcon);
    procedure SetFolder(Value: TIcon);
  public
    constructor Create();
    destructor Destroy(); override;
  published
    property Plus: TIcon read FPlus write SetPlus;
    property Minus: TIcon read FMinus write SetMinus;
    property Desktop: TIcon read FDesktop write SetDesktop;
    property MyDocs: TIcon read FMyDocs write SetMyDocs;
    property HardDrive: TIcon read FHardDrive write SetHardDrive;
    property CDRom: TIcon read FCDRom write SetCDRom;
    property Folder: TIcon read FFolder write SetFolder;
  end;

tak, by była tylko jedna procedura dla wszystkich siedmiu ikon? Czy jest taka możliwość? Próbowałem to zrobić, ale nie wiadomo co wpisać w ciele tej procedury; Przydało by się coś takiego jak Self dla tych ikon, ale nie ma;

Ma ktoś jakiś pomysł? Trochę to dziadoskie rozwiązanie, bo gdybym miał grupę, która będzie przechowywać 100 ikon (czy ogólnie grafik) to musiałbym 100 osobnych procedur pisać mimo tego, że wszystkie byłyby jednego typu... Jak można to skrócić?

edytowany 2x, ostatnio: flowCRANE 2011-11-16 09:48

cimak

2011-11-16 11:50

cimak2011-11-16 11:50

Rejestracja:ponad 22 lata
Ostatnio:ponad 9 lat
Postów:1668

nie szukales, nieladnie...
http://www.delphibasics.co.uk/RTL.asp?Name=Property
Index

edytowany 2x, ostatnio: cimak 2011-11-16 11:51

flowCRANE

2011-11-16 20:58

flowCRANE2011-11-16 20:58

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12164

No tak, przyznaję się, lenia dostałem...

Kopiuj

fCoords : array[0..3] of Longint;

Można by, ale musiałbym ikony przechowywać w tablicy, a tego nie robię; Choć nawet, gdybym tak zrobił to nie chcę wiedzieć co by się działo w Object Inspector... :P

W każdym razie jak ukończę pracę przy tym komponencie i będę pewny, że działa w 100% to dopiero wtedy spróbuję pakować te ikony do tablicy;

Efekt końcowy:

FoldersListBox.png (9 KB) - ściągnięć: 145

edytowany 3x, ostatnio: flowCRANE 2011-11-16 23:45

cimak

2011-11-17 01:02

cimak2011-11-17 01:02

Rejestracja:ponad 22 lata
Ostatnio:ponad 9 lat
Postów:1668

Furious Programming napisał(a)

No tak, przyznaję się, lenia dostałem...

Kopiuj

fCoords : array[0..3] of Longint;

no dostales i to wiekszego niz myslisz skoro Ci sie nawet nie chce w temat zaglebic...

Furious Programming napisał(a)

musiałbym ikony przechowywać w tablicy, a tego nie robię;

po jaką cholerę w tablicy? przyjrzyj sie. przeciez mozesz to zastosowac dla istniejacych zmiennych -jesli tak Ci wygodniej- wystarczy uzyc we wspolnym setterze:

Kopiuj

  case index of

i w zaleznosci od indeksu przypisywac nowa wartosc do wybranej zmiennej....

edytowany 3x, ostatnio: cimak 2011-11-17 01:13

flowCRANE

2011-11-17 19:01

flowCRANE2011-11-17 19:01

Moderator Delphi/Pascal

Rejestracja:ponad 13 lat
Ostatnio:około 3 godziny
Lokalizacja:Tuchów
Postów:12164

Matko święta, no przecież... Gdzie ja miałem głowę jak to pisałem...

edytowany 1x, ostatnio: flowCRANE 2011-11-17 19:01

Liczba odpowiedzi na stronę

Treść *

Treść

Podgląd

Kliknij, aby dodać treść...

Kliknij, aby dodać załącznik lub wklej ze schowka.

Instrukcja obsługi Markdown

Pomoc 1.18.8

Typografia

Edytor obsługuje składnie Markdown, w której pojedynczy akcent *kursywa* oraz _kursywa_ to pochylenie. Z kolei podwójny akcent **pogrubienie** oraz __pogrubienie__ to pogrubienie. Dodanie znaczników ~~strike~~ to przekreślenie.

Możesz dodać formatowanie komendami , , oraz .

Ponieważ dekoracja podkreślenia jest przeznaczona na linki, markdown nie zawiera specjalnej składni dla podkreślenia. Dlatego by dodać podkreślenie, użyj underline.

Komendy formatujące reagują na skróty klawiszowe: Ctrl+B, Ctrl+I, Ctrl+U oraz Ctrl+S.

Linki

By dodać link w edytorze użyj komendy lub użyj składni [title](link). URL umieszczony w linku lub nawet URL umieszczony bezpośrednio w tekście będzie aktywny i klikalny.

Jeżeli chcesz, możesz samodzielnie dodać link: <a href="link">title</a>.

Wewnętrzne odnośniki

Możesz umieścić odnośnik do wewnętrznej podstrony, używając następującej składni: [[Delphi/Kompendium]] lub [[Delphi/Kompendium|kliknij, aby przejść do kompendium]]. Odnośniki mogą prowadzić do Forum 4programmers.net lub np. do Kompendium.

Wspomnienia użytkowników

By wspomnieć użytkownika forum, wpisz w formularzu znak @. Zobaczysz okienko samouzupełniające nazwy użytkowników. Samouzupełnienie dobierze odpowiedni format wspomnienia, zależnie od tego czy w nazwie użytkownika znajduje się spacja.

Znaczniki HTML

Dozwolone jest używanie niektórych znaczników HTML: <a>, , , <kbd>, <del>, , <dfn>, <pre>, <blockquote>, <hr/>, ,  oraz <img/>.

Skróty klawiszowe

Dodaj kombinację klawiszy komendą notacji klawiszy lub skrótem klawiszowym Alt+K.

Reprezentuj kombinacje klawiszowe używając taga <kbd>. Oddziel od siebie klawisze znakiem plus, np <kbd>Alt+Tab</kbd>.

Indeks górny oraz dolny

Przykład: wpisując H2O i m2 otrzymasz: H₂O i m².

Składnia Tex

By precyzyjnie wyrazić działanie matematyczne, użyj składni Tex.

<tex>arcctg(x) = argtan(\frac{1}{x}) = arcsin(\frac{1}{\sqrt{1+x^2}})</tex>

Kod źródłowy

Krótkie fragmenty kodu

Wszelkie jednolinijkowe instrukcje języka programowania powinny być zawarte pomiędzy obróconymi apostrofami: `kod instrukcji` lub ``console.log(`string`);``.

Kod wielolinijkowy

Dodaj fragment kodu komendą . Fragmenty kodu zajmujące całą lub więcej linijek powinny być umieszczone w wielolinijkowym fragmencie kodu. Znaczniki ``` lub ~~~ umożliwiają kolorowanie różnych języków programowania. Możemy nadać nazwę języka programowania używając auto-uzupełnienia, kod został pokolorowany używając konkretnych ustawień kolorowania składni:

```javascript document.write('Hello World'); ```

Możesz zaznaczyć również już wklejony kod w edytorze, i użyć komendy by zamienić go w kod. Użyj kombinacji Ctrl+`, by dodać fragment kodu bez oznaczników języka.

Tabelki

Dodaj przykładową tabelkę używając komendy . Przykładowa tabelka składa się z dwóch kolumn, nagłówka i jednego wiersza.

Wygeneruj tabelkę na podstawie szablonu. Oddziel komórki separatorem ; lub |, a następnie zaznacz szablonu.

nazwisko;dziedzina;odkrycie
Pitagoras;mathematics;Pythagorean Theorem
Albert Einstein;physics;General Relativity
Marie Curie, Pierre Curie;chemistry;Radium, Polonium

Użyj komendy by zamienić zaznaczony szablon na tabelkę Markdown.

Lista uporządkowana i nieuporządkowana

Możliwe jest tworzenie listy numerowanych oraz wypunktowanych. Wystarczy, że pierwszym znakiem linii będzie * lub - dla listy nieuporządkowanej oraz 1. dla listy uporządkowanej.

Użyj komendy by dodać listę uporządkowaną.

1. Lista numerowana
2. Lista numerowana

Użyj komendy by dodać listę nieuporządkowaną.

* Lista wypunktowana
* Lista wypunktowana
** Lista wypunktowana (drugi poziom)

Składnia Markdown

Edytor obsługuje składnię Markdown, która składa się ze znaków specjalnych. Dostępne komendy, jak formatowanie , dodanie tabelki lub fragmentu kodu są w pewnym sensie świadome otaczającej jej składni, i postarają się unikać uszkodzenia jej.

Dla przykładu, używając tylko dostępnych komend, nie możemy dodać formatowania pogrubienia do kodu wielolinijkowego, albo dodać listy do tabelki - mogłoby to doprowadzić do uszkodzenia składni.

W pewnych odosobnionych przypadkach brak nowej linii przed elementami markdown również mógłby uszkodzić składnie, dlatego edytor dodaje brakujące nowe linie. Dla przykładu, dodanie formatowania pochylenia zaraz po tabelce, mogłoby zostać błędne zinterpretowane, więc edytor doda oddzielającą nową linię pomiędzy tabelką, a pochyleniem.

Skróty klawiszowe

Skróty formatujące, kiedy w edytorze znajduje się pojedynczy kursor, wstawiają sformatowany tekst przykładowy. Jeśli w edytorze znajduje się zaznaczenie (słowo, linijka, paragraf), wtedy zaznaczenie zostaje sformatowane.

Ctrl+B - dodaj pogrubienie lub pogrub zaznaczenie
Ctrl+I - dodaj pochylenie lub pochyl zaznaczenie
Ctrl+U - dodaj podkreślenie lub podkreśl zaznaczenie
Ctrl+S - dodaj przekreślenie lub przekreśl zaznaczenie

Notacja Klawiszy

Alt+K - dodaj notację klawiszy

Fragment kodu bez oznacznika

Alt+C - dodaj pusty fragment kodu

Skróty operujące na kodzie i linijkach:

Alt+L - zaznaczenie całej linii
Alt+, Alt+ - przeniesienie linijki w której znajduje się kursor w górę/dół.
Tab/⌘+] - dodaj wcięcie (wcięcie w prawo)
Shit+Tab/⌘+[ - usunięcie wcięcia (wycięcie w lewo)

Dodawanie postów:

Ctrl+Enter - dodaj post
⌘+Enter - dodaj post (MacOS)

Grupowanie właściwości

flowCRANE

flowCRANE

flowCRANE

cimak

flowCRANE

cimak

Furious Programming napisał(a)

Furious Programming napisał(a)

flowCRANE

Smileys & People

Animals & Nature

Food & Drink

Travel & Places

Activities

Objects

Symbols

Typografia

Linki

Wewnętrzne odnośniki

Wspomnienia użytkowników

Znaczniki HTML

Skróty klawiszowe

Indeks górny oraz dolny

Składnia Tex

Kod źródłowy

Krótkie fragmenty kodu

Kod wielolinijkowy

Tabelki

Lista uporządkowana i nieuporządkowana

Składnia Markdown

Skróty klawiszowe

Data Scientist

Junior Python Developer

Java Developer

Praca dla programistów

Forum dyskusyjne

Sprawy administracyjne

O nas

Skontaktuj się z nami