Prośba o skompilowanie pliku *.RES przy pomocy brcc32.exe

Witam

Chciałem skompilować plik *.RES jednak z jakichś przyczyn nie udało mi się tego zrobić. Czy mógłbym ktoś pobrać moje źródła i skompilować mi plik *.RES przy pomocy jego brcc32.exe?

Pliki BMP oraz plik RC do pobrania poniżej:
http://www.mediafire.com/?o8mqcbmo36hk98h

Z góry dziękuję :)

Pozdrawiam

Jak się nie udaje to brcc32 zgłasza błąd.
Wklej tu treść tego błędu - dostaniesz tłumaczenie jego treści.

Właśnie brcc32.exe nie wywala żadnego błędu. Okno mignie na ułamek sekundy i to tyle.

Wrzuciłem brcc32.exe, pliki *.BMP oraz plik *.RC do jednego folderu. Przygotowałem plik *.BAT a w nim:
brcc32.exe resource.rc
("resource" bo tak nazywa się folder z źródłami plików).
Uruchamiam plik BAT i...nic - okno mignie na ułamek sekundy, zero błędu i zero pliku *.RES :/

Jestem kompletnym laikiem, więc proszę o wyrozumiałość :)

Odpal konsole a z niej odpal brcc32.exe

To samo, wskazuje katalog z plikiem *.RC oraz plikami *.BMP - okno brcc32 mignie i na tym koniec T_T

Masz literówkę jak widzisz. Za dużo o jedno "r". Jeżeli nie umiesz takich błędów wychwycić to używaj tego: http://oby.ro/rad_asm/resed/ - polecam, bardzo przydatny też przy pisaniu pod WinAPI i tworzeniu dialogów.

Microsoft Windows [Wersja 6.1.7601]                                   
Copyright (c) 2009 Microsoft Corporation. Wszelkie prawa zastrzeżone. 
                                                                      
D:\!>build.bat                                                        
Nie można odnaleźć D:\!\resource.res.                                 
Borland Resource Compiler  Version 5.40                               
Copyright (c) 1990, 1999 Inprise Corporation.  All rights reserved.   
                                                                      
Error resource.rc 8 18: Cannot open file: rresource\FCPressed.bmp     
Error(s) - press any key...

A do tworzenia na przykład pod Delphi 7 projektów i od razu wcześniejszego przebudowania zasobów, paknięcia upx'em i wywalenia zbędnych *.dcu polecam taki batch. Oczywiście wszystko co użyte z zewnętrznych programów musi być w %PATH%.

@echo off
setlocal ENABLEDELAYEDEXPANSION
set dcu_output_path=.\DCU
for %%I in (*.exe) do (
  if exist %%~nI.dpr taskkill /im %%~nxI /f
  if exist %%~nI.dpr del %%~nxI
)

for %%I in (*.dpr) do (
  dcc32 %%~nI.dpr
)

for %%I in (*.rc) do (
  del %%~nI.res
  brcc32 %%~nI.rc -fo %%~nI.res
  if not !errorlevel! == 0 goto show_error
)

for %%I in (*.dpr) do (
  dcc32 %%~nI.dpr
  if not !errorlevel! == 0 goto show_error
)
for %%I in (*.dll) do (
  if exist %%~nI.dpr (
      upx --best %%~nxI
      if not !errorlevel! == 0 goto show_error
  )
)

for %%I in (*.exe) do (
  if exist %%~nI.dpr (
    if exist *.dfm (
      upx --best --lzma %%~nxI
      if not !errorlevel! == 0 goto show_error
    ) else (
      upx --best %%~nxI
      if not !errorlevel! == 0 goto show_error
    )
  )
)

if exist %dcu_output_path% (
  cd %dcu_output_path%
  del *.dcu
  cd ..
) else (
  for %%I in (*.dcu) do (
    if exist %%~nI.pas del %%~nI.dcu
  )
)
goto the_end

:show_error
echo Error(s) - press any key...
pause > nul

:the_end

1. olesio - dzięki za przeniesienie. Wybacz zamieszanie.
2. Faktycznie...miałem literówkę T_T Sprawdzałem plik *.RC 2 razy, a i tak przeoczyłem...
3. Dzięki. Wszystko tańczy i śpiewa.

Pozdrawiam

//Do zamknięcia.