Jak rozbudować typ o nowe kolumny

Witajcie mam sobie typ nazwijmy go T_MY_ROWTYPE

CREATE OR REPLACE TYPE T_MY_ROWTYPE is OBJECT(
  id NUMBER(10),
  qcards_nr NUMBER(2,0),
  rodzaj NUMBER(19,0),
  kto_utworzyl VARCHAR2(30 CHAR),
  constructor function T_MY_ROWTYPE(
  SELF IN OUT NOCOPY T_MY_ROWTYPE,
  id NUMBER,
  qcards_nr NUMBER default 1,
  rodzaj NUMBER default null,
  kto_utworzyl VARCHAR2 default null
  ) RETURN SELF AS RESULT
 )

CREATE OR REPLACE TYPE BODY T_MY_ROWTYPE AS
    CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null)  RETURN SELF AS RESULT IS
    BEGIN
        SELF.ID := id;
        SELF.qcards_nr := qcards_nr;
        SELF.rodzaj := rodzaj;
        SELF.kto_utworzyl := kto_utworzyl;
        RETURN;
    END;    
END;

Dodatkowo mam tabelę jak poniżej:

CREATE TABLE MY_TABLE (
  "KAD_ID" NUMBER NOT NULL,
  "KAD_PARAMS" T_MY_ROWTYPE NOT NULL
)  

W obecnej formie wszystko działa jak należy i taki kod:

begin
  PROCKA_ROBIACA_INSERT(1,T_MY_ROWTYPE(123,9,null,'alamakota'));
  PROCKA_ROBIACA_INSERT(2,T_MY_ROWTYPE(123));
end;

Działa bez problemu czyli mogę używać tylko 1 lub z wieloma parametrami.

Teraz chciałbym rozbudować ten typ (który przypominam jest już kolumną w tabeli - a to utrudnia pewne rzeczy bo nie chcę np usuwać typu i tworzyć nowego) o nową kolumnę. Robię zatem:

ALTER TYPE T_MY_ROWTYPE ADD ATTRIBUTE (id_org number(10)) CASCADE

ALTER TYPE T_MY_ROWTYPE
    ADD constructor function T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null,
      id_org number default null) RETURN SELF AS RESULT
    CASCADE

CREATE OR REPLACE TYPE BODY T_MY_ROWTYPE AS
    CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null)  RETURN SELF AS RESULT IS
    BEGIN
        SELF.ID := id;
        SELF.qcards_nr := qcards_nr;
        SELF.rodzaj := rodzaj;
        SELF.kto_utworzyl := kto_utworzyl;
        RETURN;
    END;
    CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null,
      id_org number default null)  RETURN SELF AS RESULT IS
    BEGIN
        SELF.ID := id;
        SELF.qcards_nr := qcards_nr;
        SELF.rodzaj := rodzaj;
        SELF.kto_utworzyl := kto_utworzyl;
        SELF.id_org := id_org;
        RETURN;
    END;
END;

Teorytycznie wszystko się poprawnie wykonało. Dodał się nowy atrybut oraz nowy konstruktor przeładowany. Niestety w tej postaci to:

begin
  PROCKA_ROBIACA_INSERT(2,T_MY_ROWTYPE(123));
end;

nie działa wcale

a to:

begin
  PROCKA_ROBIACA_INSERT(1,T_MY_ROWTYPE(123,9,null,'alamakota',99));
end;

nie odkłada tego 99 w tabeli. Pomożecie?

Nie używaj ALTER. To złamie kompatybilność wsteczną dla encji ORMowych. To co powinieneś zrobić to zdefiniować nową tabelę z kluczem obcym z oryginalnej. Później stworzyć widok.

Tak zachowasz wsteczną kompatybilność.

A stworzenie niedziałającej procki na nowo?
To samo źródło, tylko po to, by "uaktualnił" sobie parametry wejściowe...

Podstawowym problemem jest to, że gdy typ obiektowy jest już używany (np. jako kolumna tabeli), jego konstruktor "zamraża się" w pierwotnej wersji - zatem:

Po dodaniu nowego atrybutu (id_org) oraz przeciążonego konstruktora, nadal mam oryginalny konstruktor przyjmujący cztery parametry (z domyślnymi wartościami dla qcards_nr, rodzaj, kto_utworzyl). Jednakże – gdy typ jest już zapisany w tabeli – Oracle przy wywołaniu T_MY_ROWTYPE(123) nadal interpretuje to wg oryginalnej definicji, która już nie odpowiada aktualnej strukturze typu (bo teraz mamy pięć atrybutów). W efekcie wywołanie to przestaje działać lub generuje niespójny stan obiektu.

Nawet gdy wywołam nową wersję z pięcioma parametrami T_MY_ROWTYPE(123,9,null,'alamakota',99), Oracle przy kompilacji i przy wywołaniu może nadal korzystać z oryginalnego konstruktora – albo następuje konflikt przeciążenia – w rezultacie wartość przekazana jako 99 nie trafia do atrybutu id_org. Dlatego wstawiony rekord nie zawiera oczekiwanej wartości, a nowy atrybut pozostaje NULL.

Gdy typ obiektowy zostanie już użyty w definicjach tabel lub innych strukturach, mechanizm rozpoznawania konstruktora opiera się na pierwotnej definicji. Modyfikacja typu nie powoduje "odświeżenia" wywołań konstruktora w już istniejących obiektach SQL. I CASCADE po prostu nie działa. W efekcie dodanie przeciążonego konstruktora nie powoduje zastąpienia lub rozszerzenia sposobu tworzenia instancji – pozostaje konflikt między starą a nową definicją.

Taką informację otrzymałem od kogoś bardziej doświadczonego z typami obiektowymi niż ja także nie da się i już. Trzeba by usunąć kolumnę/tabelę z tym typem zdropować typ i utworzyć nowy typ z rozbudowanym konstruktorem.

Natomiast odpowiadając na pytanie po co mi to ... to już nie jest istotne mam taki konkrety przypadek i muszę się z nim uporać.

woolfik napisał(a):

Podstawowym problemem jest to, że gdy typ obiektowy jest już używany (np. jako kolumna tabeli), jego konstruktor "zamraża się" w pierwotnej wersji - zatem:
(...)

Ja wiem, że to pewnie po ptokach, ale wywala się, bo w typie masz dwa (dodatkowe) konstruktory:

CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null)  RETURN SELF AS RESULT IS

CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null,
      id_org number default null)  RETURN SELF AS RESULT IS

Jak robisz wywołanie T_MY_ROWTYPE(123), to nie wiadomo, którego ma użyć, bo pasują oba (id podane explicite, ale default null na reszcie pól pasuje do obu).
Widoczne to będzie, jak zrobisz sobie zwykłe

INSERT INTO MY_TABLE(KAD_ID, KAD_PARAMS) values (3, T_MY_ROWTYPE(456));

Dostaniesz ORA ładnie opisujące, co jest źle.

Tak czy inaczej nowa wersja z 5 parametrami (T_MY_ROWTYPE(123,9,null,'alamakota',99)) na poziomie insert into działa i wstawia 99 do ostatniego pola.

Pytanie, czym jest "PROCKA_ROBIACA_INSERT".
Bo imo wywołanie

PROCKA_ROBIACA_INSERT(1,T_MY_ROWTYPE(123,9,null,'alamakota',99));

przekaże parametr z 5 polami, no ale to już kwestia tego, co tam pod spodem jest w "PROCKA_ROBIACA_INSERT".

Aaa, i jeszcze jedno.
Chyba nie trzeba dropować kolumny, wystarczy przy zmianie definicji typu usunąć stary konstruktor:

ALTER TYPE T_MY_ROWTYPE
    DROP constructor function T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null) RETURN SELF AS RESULT
    CASCADE

CREATE OR REPLACE TYPE BODY T_MY_ROWTYPE AS
    CONSTRUCTOR FUNCTION T_MY_ROWTYPE(
      SELF IN OUT NOCOPY T_MY_ROWTYPE,
      id NUMBER,
      qcards_nr NUMBER default 1,
      rodzaj NUMBER default null,
      kto_utworzyl VARCHAR2 default null,
      id_org number default null)  RETURN SELF AS RESULT IS
    BEGIN
        SELF.ID := id;
        SELF.qcards_nr := qcards_nr;
        SELF.rodzaj := rodzaj;
        SELF.kto_utworzyl := kto_utworzyl;
        SELF.id_org := id_org;
        RETURN;
    END;
END;

@Los Bomberos twoje rozwiązanie zadziałało wywalenie starego konstruktora dodanie atrybutu i dodanie nowego konstruktora z defaultem zadziałało nawet na typie, ktory już był dodany do tabeli wielkie dzięki wisze Ci dużego browara