Asembler uruchamiany przez bios - pisanie na ekran

arczi28

2015-11-16T13:13:04+01:00

Rejestracja: dni
Ostatnio: dni
Postów: 17

0

Witam serdecznie :)

od niedawna uczę sie Assemblera, i chciałbym wykonać coś takiego:

Kopiuj

mov ah,0h
mov al,03h
int 10h

mov ax,0xb800
mov es,ax
xor di,di
mov si,napis

mov cx,14
rep movsb 


napis db "taki tam napis" ;; witam tutaj powinna być literka i następny bajt z informacją o kolorze ale na potrzeby tego postu jest to nieistotne

i gdy włączę tak skompilowany kod w DosBox na ekranie pojawia się "taki tam napis" jednak gdy dodam flagi boot aby zostało to uruchomione przez bios (Virtual PC) na ekranie nie pojawia się biały pasek lub po prostu nic.. tak jak by coś zostało źle zaadresowane... nie rozumiem co jest nie tak...
(po dodaniu flag boot, oczywiście wypełniam program do pełnych 512 bajtów)
Być może zrobiłem wszystko źle...
Bardzo będę wdzięczny za pomoc..

podobanie mam z funkcją 13h przerwania 10h (write string)
nie działa poprawnie gdy uruchomię program w Virtual PC. Dlaczego? przecież nie jest to przerwanie DOS-a.

Proxima

2015-11-16T14:39:42+01:00

Rejestracja: dni
Ostatnio: dni
Lokalizacja: Pomorskie (Stare Kabaty)

0

Powinieneś sciągnać sobie emulator jakiś przyjemniejszy niż Virtual PC, przykładowo bochs z debuggerem graficznym, to tak na początek.
Jak x86 bootuje to ty wiesz, nie?;
Jak nie wiesz to słuchaj, jest mniej więcej tak.

Jest sobie POST, i jeśli będzie POST OK to jedziem dalej
Ładuje się bootloader pod adres absolutny 0x7C00
I to w sumie tyle, dalej w internalsach BIOSa pewnie jest jmp 0x0000:0x07c0 i kod się wykonuje.
ALE, pewne rzeczy trzeba zrobić, otóż stan rejestrów jest niezdefiniowany w tym momencie (głowy nie dam sobie uciąć o to), a nawet jeśli jest zdefiniowany to przez BIOSa, i nam on nie odpowiada.
Musisz ustawić odpowiednio rejestry segmentowe coby to się nie sypneło wszystko.
Mapkę pamięci BIOSu masz tu
Czyli finalnie to będzie wyglądać tak, ustawione tu rejestry są wybrane z mapki przeze mnie i możesz sobie to zmienić, a w razie pytań pisz.

Kopiuj

; MOŻE COS NIE PYKAĆ BO W EDYTORZE NA FORUM PISANE, NIE BIĆ :-P
; ustaw segmenty
mov ax, 0x07c0
mov ds, ax
mov es, ax

; ustaw stos
mov ax, 0x0050
mov ss, ax
mov sp, 0x0000

jmp loopy_loop
; == TU MIEJSCE NA TWOJE FUNKCJE ==
; in = si -> char*
print_string:
    push ax
    push si
        .loop_char:
         lodsb
         cmp al, 0x0
         je .end
         mov ah, 0xe
         int 0x10
         jmp .loop_char
       .end:
       pop si
       pop ax
       ret

loopy_loop:
    mov si, msg_booted
    call print_string
    .hang:
    cli
    hlt

msg_booted db "Booted :-)", 13, 10, 0
db 0x55
db 0xAA

arczi28

2015-11-16T15:06:05+01:00

Rejestracja: dni
Ostatnio: dni
Postów: 17

0

Dziękuje Proxima za odpowiedź,
bootloader jest kompilowany osobno, ładuje następny sektor i wczytuję go do adresu 0x0800 wygląda to tak

Kopiuj

org 7c00h

start:

  mov ah, 2
  mov al, 10
  mov ch, 0
  mov cl, 2
  mov dh, 0
  mov bx, 800h
  mov es, bx
  xor bx, bx
  int 13h
 
  jmp 800h:0000h



times 510 - ($ - start) db 0
 
db 55h
db 0AAh

i osobno kompilowałem program z próbą wyrzucenia tekstu na ekran....
po ustawieniu stosu i segmentów.. nadal nic nie działa..a na DosBox program także zaczął się wysypywać... ale to już domyślam się dlaczego... :)

próbowałem także czegoś takiego...

Kopiuj

lea si,[napisy]  ;; 

napis:
mov ah,0Eh
mov al,[si]
int 10h
inc si

cmp al,'$' ;tak wiem... jeśli już zadziała to pokaże się $ ale to nie istotne ;)
jz exitos

jmp napis


exitos:  
;coś tam dalej..


napisy db "napis"

Uczę się dopiero... jednak nie mogę znaleźć nic sensownego w tej kwestii.. podstawy asma znam bo wykorzystuję go w C++

Proxima

2015-11-16T15:10:57+01:00

Rejestracja: dni
Ostatnio: dni
Lokalizacja: Pomorskie (Stare Kabaty)

0

Dobra, zrób tak.
Ustaw odpowiednio rejestry w bootloaderze i wypisz (z poziomu bootloadera) jakiś napis. Ładowaniem stage1 będziemy się martwić później.
I Ogarnij może bochsa, bo bez debuggera taki kod naprawiać to potrafi być denerwujące mocno, szczególnie jak sie to kiepsko jescze ogarnia : D
//edit2
tak patrze na tą funkcje co ładuje stage1 i coś mnie ona śmierdzi, dam ci swoją najwyżej.

arczi28

2015-11-16T15:39:47+01:00

Rejestracja: dni
Ostatnio: dni
Postów: 17

0

Teraz to mi ręce opadły... albo oślepłem i już czegoś nie widzę....
oto cały kod bootloadera - oczywiście nie działa....

Kopiuj

org 7c00h


start:

mov ax, 0x7c00     ; segmenty...
mov ds, ax
mov es, ax
 

mov ax, 0x0050 ; ustawiam stos
mov ss, ax
mov sp, 0x0000


mov ah,0h        ; tryb vga tekstowy
mov al,03h
int 10h

mov ah,13h   ; fukcja wrte string
mov al,1h ; atrybut ma być w bl i kursor ma iść dalej..
mov bp,napisy  ;;wiadomo...
mov bl,7
mov bh,0
mov cx,6
mov dh,1
mov dl,1
int 10h ; i start

xor ax,ax ; tak tylko żeby zatrzymac
int 16h





napisy db "coś tam";

times 510 - ($ - start) db 0
 
db 55h
db 0AAh

nie wiem już co jest... ale kursor zmienia pozycję.. ale tekstu brak

Proxima

2015-11-16T16:03:36+01:00

Rejestracja: dni
Ostatnio: dni
Lokalizacja: Pomorskie (Stare Kabaty)

0

Nic nie ma opadać tylko szukać trzeba w gugielu.
Masa zbędnego kodu jest u ciebie, to od początku.
Główny błąd jest tu mov ax, 0x7c00 ; segmenty... i tu org 7c00h
Otóż adres absolutny w rmode to się liczy segment * 16 + offset i co tu nam wyjdzie?
Sprawdźmy.

Kopiuj

 
Disassembly of section .data:
00000000 <.data>:
   0:   b8 00 7c                mov    ax,0x7c00 ; tu pacz
   3:   8e d8                   mov    ds,ax
   5:   8e c0                   mov    es,ax
   7:   b8 50 00                mov    ax,0x50
   a:   8e d0                   mov    ss,ax
   c:   bc 00 00                mov    sp,0x0
   f:   eb 10                   jmp    0x21
  11:   50                      push   ax
  12:   56                      push   si
  13:   ac                      lods   al,BYTE PTR ds:[si]
  14:   3c 00                   cmp    al,0x0
  16:   74 06                   je     0x1e
  18:   b4 0e                   mov    ah,0xe
  1a:   cd 10                   int    0x10
  1c:   eb f5                   jmp    0x13
  1e:   5e                      pop    si
  1f:   58                      pop    ax
  20:   c3                      ret    
  21:   be 29 7c                mov    si,0x7c29 ; tu pacz < -- to powoduje org
  24:   e8 ea ff                call   0x11
  27:   fa                      cli    
  28:   f4                      hlt    
  29:   48                      dec    ax
  2a:   65 6c                   gs ins BYTE PTR es:[di],dx
  2c:   6c                      ins    BYTE PTR es:[di],dx
  2d:   6f                      outs   dx,WORD PTR ds:[si]
  2e:   21 21                   and    WORD PTR [bx+di],sp
  30:   21 21                   and    WORD PTR [bx+di],sp
  32:   31 31                   xor    WORD PTR [bx+di],si
  34:   31 6f 6e                xor    WORD PTR [bx+0x6e],bp
  37:   65 6f                   outs   dx,WORD PTR gs:[si]
  39:   6e                      outs   dx,BYTE PTR ds:[si]
  3a:   65 6f                   outs   dx,WORD PTR gs:[si]
  3c:   6e                      outs   dx,BYTE PTR ds:[si]
  3d:   65 0d 0a 00             gs or  ax,0xa
        ...
 1fd:   00 55 aa                add    BYTE PTR [di-0x56],dl

czyyli segment = 0x7c00, offset = 0x7c29

Kopiuj

$python
>>> hex((0x7c00*16) + 0x7c29)
'0x83c29'

no, nieco za dużo, to trzeba już w pmode robić.
Skorygowany kod.

Kopiuj

start:

; set segments
mov ax, 0x07c0
mov ds, ax
mov es, ax

; set stack
mov ax, 0x0050
mov ss, ax
mov sp, 0x0000


jmp loopy_loop

print_string:
    push ax
    push si
        .loop_char:
            lodsb
            cmp al, 0x0
            je .done
            mov ah, 0xe
            int 0x10
            jmp .loop_char
    .done:
        pop si
        pop ax
        ret

loopy_loop:
    mov si, hello_hello
    call print_string

    cli
    hlt


hello_hello db "Hello!!!!111oneoneone", 13, 10, 0

times 510 - ($ - start) db 0
db 0x55
db 0xAA

Przy poprawnym kodzie, offset absolutny wyjdzie nam '0x7c29', czyli jest oke.

CorruptedByCPU

2015-11-24T18:15:55+01:00

Rejestracja: dni
Ostatnio: dni
Postów: 211

0

Proszę bardzo, działający fragment z mojego systemu operacyjnego.

Kompiluj za pomocą Nasm:
nasm -f bin test.asm -o disk.raw

Uruchamiaj za pomocą Qemu:
qemu.exe -hda disk.raw

Kod:

Kopiuj

; Copyright (C) 2013-2015 Wataha.net
; All Rights Reserved
;
; LICENSE Creative Commons BY-NC-ND 4.0
; See LICENSE.TXT
;
; Main developer:
;	Andrzej (akasei) Adamczyk [e-mail: akasei from wataha.net]
;-------------------------------------------------------------------------------

; Use:
; nasm - http://www.nasm.us/

; 16 bitowy kod programu
[BITS 16]

; położenie kodu programu w pamięci fizycznej 0x0000:0x7C00
[ORG 0x7C00]

start:
	; wyłącz przerwania
	cli

	; niektóre BIOSy mogą ustawiać niepoprawny segment kodu tj. 0x07C0:0x0000
	; wykonaj daleki skok, by naprawić tą przypadłość
	jmp	0x0000:repair_cs

repair_cs:
	; wyczyść AX
	xor	ax,	ax

	; ustaw segmenty danych, ekstra i stosu na pierwsze 64 KiB pamięci fizycznej
	mov	ds,	ax	; segment danych
	mov	es,	ax	; segment ekstra
	mov	ss,	ax	; segment stosu

	; ustaw wskaźnik stosu na "koniec" segmentu danych/stosu
	xor	sp,	sp

	; włącz przerwania
	sti

	; wyświetl informację o przystąpieniu do pracy
	mov	si,	text_ready
	call	print_16bit

	; zatrzymaj wykonywanie dalczego kodu programu
	jmp	$

print_16bit:
	; zachowaj oryginalne rejestry
	push	ax
	push	si

	; procedura - wyświetl znak w miejscu kursora, przesuń kursor w prawo
	mov	ah,	0x0E

.loop:
	; pobierz do AL wartość z adresu pod wskaźnikiem SI, zwiększ wskaźnik SI o 1
	lodsb

	; sprawdź czy koniec tekstu do wyświetlenia
	cmp	al,	0x00	; jeśli ZERO, zakończ
	je	.end

	; wyświetl znak na ekranie
	int	0x10

	; załaduj i wyświetl następny znak
	jmp	.loop

.end:
	; przywróć oryginalne rejestry
	pop	si
	pop	ax

	; powrót z procedury
	ret

text_ready			db	'Bootloader ready.', 0x0A, 0x0D, 0x00

; uzupełniamy niewykorzystaną przestrzeń
times	510 - ( $ - $$ )	db	0x00

; znacznik sektora rozruchowego	
dw	0xAA55	; czysta magija

Azarien

2015-11-24T20:35:23+01:00

Rejestracja: dni
Ostatnio: dni

0

Kopiuj

    ; wyczyść AX
    xor    ax,    ax
 
    ; ustaw segmenty danych, ekstra i stosu na pierwsze 64 KiB pamięci fizycznej

Bardzo kiepski pomysł, pod adresem 0000:0000 masz tablicę wektorów przerwań, a ty chcesz tam mieć dane i stos.

Kopiuj

    ; wyłącz przerwania
    cli

Kopiuj

    ; włącz przerwania
    sti

to po co było to wyłączanie?

CorruptedByCPU

2015-11-24T21:37:29+01:00

Rejestracja: dni
Ostatnio: dni
Postów: 211

0

Lol, nie :) Gdy odłożysz na stos pierwszą wartość, licznik SP się przekręca i wskazuje na koniec segmentu danych SS/DS czyli 0xFFF8 :D Tablica wektorów przerwań jest nienaruszona! Natomiast przy modyfikacji rejestrów segmentowych, zawsze bezpieczniej jest wyłączyć obsługę przerwań.